home *** CD-ROM | disk | FTP | other *** search
/ QRZ! Ham Radio 8 / QRZ Ham Radio Callsign Database - Volume 8.iso / pc / files / dsp / 56000tar.z / 56000tar / 56000 / speech / adpcm.asm next >
Assembly Source File  |  1991-11-26  |  121KB  |  3,107 lines
  1. ;
  2. ; This program originally available on the Motorola DSP bulletin board.
  3. ; It is provided under a DISCLAMER OF WARRANTY available from
  4. ; Motorola DSP Operation, 6501 Wm. Cannon Drive W., Austin, Tx., 78735.
  5. ; 
  6. ;**************************************************************************
  7. ;
  8. ;   ADPCM.ASM       Full-Duplex 32-kbit/s CCITT ADPCM Algorithm
  9. ;
  10. ; Version 1.0 - 1/27/89
  11. ;
  12. ; This program implements the algorithm defined in CCITT Recommendation
  13. ; G.721: "32 kbit/s Adaptive Differential Pulse Code Modulation" dated
  14. ; August 1986. This version passes all of the mu-law and A-law test
  15. ; sequences as defined in Appendix II of Recommendation G.721.
  16. ;
  17. ; Please refer to the file ADPCM.HLP for further information about
  18. ; this program.
  19. ;
  20. ;**************************************************************************
  21.  
  22.             OPT     CC,CEX                                                                         
  23.  
  24. START       EQU     $0040
  25.  
  26.             ORG     X:$0000
  27.  
  28. ;******************** Encoder variables ***********************************
  29. ;   I = siii 0000 | 0000 0000 | 0000 0000 (ADPCM format)
  30. I_T         DS      1               ;ADPCM codeword
  31. ;   DQ = siii iiii | iiii iii.0 | 0000 0000  (15SM)
  32. DQ_T        DS      1               ;Quantized difference signal
  33. ;   Y = 0iii i.fff | ffff ff00 | 0000 0000  (13SM)
  34. Y_T         DS      1               ;Quantizer scale factor
  35. ;   AP = 0ii.f ffff | fff0 0000 | 0000 0000  (10SM)
  36. AP_T        DS      1               ;Unlimited speed control parameter
  37. ;   AL = 0i.ff ffff | 0000 0000 | 0000 0000  (7SM)
  38. AL_T        DS      1               ;Limited speed control parameter
  39.  
  40. ;******************** Decoder variables ***********************************
  41. I_R         DS      1               ;ADPCM codeword
  42. DQ_R        DS      1               ;Quantized difference signal
  43. Y_R         DS      1               ;Quantizer scale factor
  44. AP_R        DS      1               ;Unlimited speed control parameter
  45. AL_R        DS      1               ;Limited speed control parameter
  46. ;   SP = psss qqqq | 0000 0000 | 0000 0000 (PCM log format)
  47. SP_R        DS      1               ;PCM reconstructed signal
  48.  
  49. ;******************** Temporary variables *********************************
  50. ;   IMAG = 0iii. 0000 | 0000 0000 | 0000 0000
  51. IMAG        DS      1               ;|I|
  52. ;   PKS1 = sXXX XXXX | XXXX XXXX | 0000 0000  (1TC)
  53. PKS1        DS      1               ;XOR of  PK0 & PK1
  54. ;   PKS2 = sXXX XXXX | XXXX XXXX | 0000 0000  (1TC)
  55. PKS2        DS      1               ;XOR of  PK0 & PK2
  56. DATAPTR_T   DS      1               ;Transmit data buffer pointer
  57. DATAPTR_R   DS      1               ;Receive data buffer pointer
  58.  
  59.  
  60. ;******************** Table for quantizing DLN ****************************
  61. ; Used in QUAN routine
  62.  
  63. QUANTAB     DS      8
  64.  
  65. ;******************** Table for unquantizing I ****************************
  66. ; Used in RECONST
  67.  
  68. IQUANTAB    DS      8
  69.  
  70. ;******************** W(I) lookup table ***********************************
  71. ; Used in FUNCTW routine
  72.  
  73. WIBASE      DS      8
  74.  
  75. ;******************** Table used in COMPRESS ******************************
  76.  
  77. TAB         DS      8
  78.  
  79. ;******************** Constants used by FMULT *****************************
  80.  
  81. CONST       DS      6
  82.  
  83. ;******************** Encoder data buffer *********************************
  84. ; DQn (11FL) stored separately as exponent, mantissa, and sign
  85. ;    DQnEXP = 0000 0000 | 0000 0000 | 0000 eeee
  86. ;    DQnMANT = 01mm mmm0 | 0000 0000 | 0000 0000
  87. ;    DQnS = sXXX XXXX | XXXX XXXX | 0000 0000
  88. ; SRn in same format
  89. DATA_T      DSM     24              ;24 word modulo buffer for data,
  90.                                     ; R2 is used as pointer, DATAPTR_T
  91.                                     ; points to start of buffer (DQ1EXP)
  92.                                     ; at beginning of cycle
  93.                                     ;DQ1EXP,DQ1MANT,DQ1S
  94.                                     ;DQ2EXP,DQ2MANT,DQ2S
  95.                                     ;DQ3EXP,DQ3MANT,DQ3S
  96.                                     ;DQ4EXP,DQ4MANT,DQ4S
  97.                                     ;DQ5EXP,DQ5MANT,DQ5S
  98.                                     ;DQ6EXP,DQ6MANT,DQ6S
  99.                                     ;SR1EXP,SR1MANT,SR1S
  100.                                     ;SR2EXP,SR2MANT,SR2S
  101.  
  102. ;******************** Encoder partial product buffer **********************
  103. ;   WBn = siii iiii | iiii iii.f | 0000 0000  (16TC)
  104. ;   WAn in same format
  105. PP_T        DSM     8               ;8 word modulo buffer for partial
  106.                                     ; products, R1 is used as pointer
  107.                                     ;WB1
  108.                                     ;WB2
  109.                                     ;WB3
  110.                                     ;WB4
  111.                                     ;WB5
  112.                                     ;WB6
  113.                                     ;WA1
  114.                                     ;WA2
  115.  
  116. ;******************** Decoder data buffer *********************************
  117. DATA_R      DSM     24              ;24 word modulo buffer for data
  118.                                     ; (same format as DATA_T)
  119.  
  120. ;******************** Decoder partial product buffer **********************
  121. PP_R        DSM     8               ;8 word modulo buffer for partial products
  122.                                     ; (same format as PP_T)
  123.     
  124.  
  125.             ORG     Y:$0000
  126. ;******************** Encoder variables ***********************************
  127. ;   SE = siii iiii | iiii iii.0 | 0000 0000  (15TC)
  128. SE_T        DS      1               ;Signal estimate
  129. ;   SEZ = siii iiii | iiii iii.0 | 0000 0000 (15TC)
  130. SEZ_T       DS      1               ;Partial signal estimate
  131. ;   SR = siii iiii | iiii iiii. | 0000 0000  (16TC)
  132. SR_T        DS      1               ;Reconstructed signal
  133. ;   PK0 = sXXX XXXX | XXXX XXXX | 0000 0000  (1TC)
  134. PK0_T       DS      1               ;Sign of DQ + SEZ
  135. ;   PK1 = sXXX XXXX | XXXX XXXX | 0000 0000  (1TC)
  136. PK1_T       DS      1               ;Delayed sign of DQ + SEZ
  137. ;   PK2 = sXXX XXXX | XXXX XXXX | 0000 0000  (1TC)
  138. PK2_T       DS      1               ;Delayed sign of DQ + SEZ
  139. ;   DMS = 0iii. ffff | ffff f000 | 0000 0000  (12SM)
  140. DMS_T       DS      1               ;Short term average of F(I)
  141. ;   DML = 0iii. ffff | ffff fff0 | 0000 0000  (14SM)
  142. DML_T       DS      1               ;Long term average of F(I)
  143. ;   TDP = i000 0000 | 0000 0000 | 0000 0000  (1TC)
  144. TDP_T       DS      1               ;Tone detect
  145. ;   TD = i000 0000 | 0000 0000 | 0000 0000  (1TC)
  146. TD_T        DS      1               ;Delayed tone detect
  147. ;   YU =  0iii i.fff | ffff ff00 | 0000 0000  (13SM)
  148. YU_T        DS      1               ;Fast quantizer scale factor
  149. ;   YL =  0iii i.fff | ffff ffff | ffff 0000  (19SM)
  150. YL_T        DS      1               ;Slow quantizer scale factor
  151. ;   SIGPK = i000 0000 | 0000 0000 | 0000 0000  (1TC)
  152. SIGPK_T     DS      1               ;Sgn[p(k)] flag
  153. ;   A2P = si.ff ffff | ffff ffff | 0000 0000 (16TC)
  154. A2P_T       DS      1               ;Second order predictor coef
  155. ;   TR = i000 0000 | 0000 0000 | 0000 0000  (1TC)
  156. TR_T        DS      1               ;Transition detect
  157.  
  158. ;******************** Decoder variables ***********************************
  159. SE_R        DS      1               ;Signal estimate
  160. SEZ_R       DS      1               ;Partial signal estimate
  161. SR_R        DS      1               ;Reconstructed signal
  162. PK0_R       DS      1               ;Sign of DQ + SEZ
  163. PK1_R       DS      1               ;Delayed sign of DQ + SEZ
  164. PK2_R       DS      1               ;Delayed sign of DQ + SEZ
  165. DMS_R       DS      1               ;Short term average of F(I)
  166. DML_R       DS      1               ;Long term average of F(I)
  167. TDP_R       DS      1               ;Tone detect
  168. TD_R        DS      1               ;Delayed tone detect
  169. YU_R        DS      1               ;Fast quantizer scale factor
  170. YL_R        DS      1               ;Slow quantizer scale factor
  171. SIGPK_R     DS      1               ;Sgn[p(k)] flag
  172. A2P_R       DS      1               ;Second order predictor coef
  173. TR_R        DS      1               ;Transition detect
  174.  
  175. ;******************** Temporary variables *********************************
  176. LAW         DS      1               ;Select A-law or mu-law
  177. DQMAG       DS      1               ;|DQ|
  178.  
  179. ;******************** Shift constant lookup table *************************
  180. ; Shift constants used for doing left or right shifts by multiplying by a
  181. ; power of 2.  For right shift, some routines use R5 as a base and N5 as
  182. ; and offset for lookup of shift constant.
  183. RSHFT       DS      24
  184. LSHFT
  185.  
  186. ;******************** Misc. constants *************************************
  187. CONST1      DS      3
  188. CONST4      DS      4
  189. CONST8      DS      9
  190. CONST17     DS      16
  191.  
  192. ;******************** Encoder coef. buffer ********************************
  193. ;   Bn = si.ff ffff | ffff ffff | 0000 0000 (16TC)
  194. ;   An in same format
  195. COEF_T      DSM     8               ;8 word modulo buffer for coefs.,
  196.                                     ; R6 is used as pointer
  197.                                     ;B1
  198.                                     ;B2
  199.                                     ;B3
  200.                                     ;B4
  201.                                     ;B5
  202.                                     ;B6
  203.                                     ;A1
  204.                                     ;A2
  205.  
  206. ;******************** Decoder coef. buffer ********************************
  207. COEF_R      DSM     8               ;8 locations for coef. queue
  208.                                     ; (same format as COEF_T)
  209.  
  210.             PAGE
  211.  
  212.             ORG     P:$0000
  213.             JMP     START
  214.  
  215.             ORG     P:START
  216.  
  217.         CLR     A
  218.         MOVEC   #$06,OMR            ;Enable internal ROM tables
  219.         MOVEP   A,X:$FFFE           ;Set BCR for 0 wait states
  220.         JSR     INIT
  221.  
  222. ;**************************************************************************
  223. ;
  224. ;   Encoder
  225. ;
  226. ;**************************************************************************
  227.  
  228. ENCODE  MOVE    #PP_T,R1            ;Set partial product ptr to WB1
  229.         MOVE    X:DATAPTR_T,R2      ;Set data pointer to DQ1EXP
  230.         MOVE    #COEF_T,R6          ;Set coef pointer to B1
  231.         MOVE    #CONST1,R7          ;Set pointer to misc constants
  232.  
  233. ;**************************************************************************
  234. ;       FMULT
  235. ;
  236. ; Multiply predictor coefficients with corresponding
  237. ;   quantized difference signal or reconstructed signal
  238. ;
  239. ;   Data (DQn or SRn) is stored in 11FL format (separate),
  240. ;   & coefficient (Bn or An) is stored in 16TC format.
  241. ;
  242. ; Computes  [An(k-1) * SR(k-n)] or [Bn(k-1) * DQ(k-n)]
  243. ;
  244. ; Flow Description:
  245. ;   1. Convert 16TC An to 13SM AnMAG
  246. ;   2. Convert 13SM AnMAG to 10FL (AnEXP and AnMANT)
  247. ;   3. Add SRnEXP to AnEXP to get WAnEXP (5-bits)
  248. ;   4. Multiply SRnMANT with AnMANT, add '48', and truncate
  249. ;       to 8-bits to get WAnMANT
  250. ;   5. Convert 13FL (WAnEXP & WAnMANT) to 15SM WAnMAG
  251. ;   6. XOR AnS with SRnS to find WAnS
  252. ;   7. Convert 16SM (WAnMAG & WAnS) to 16TC WAn
  253. ;
  254. ; Input:
  255. ;   SRn = (11FL)
  256. ;    SRnEXP = X:(R2) = 0000 0000 | 0000 0000 | 0000 eeee
  257. ;    SRnMANT = X:(R2+1) = 01mm mmm0 | 0000 0000 | 0000 0000
  258. ;    SRnS = X:(R2+2) = sXXX XXXX | XXXX XXXX | 0000 0000
  259. ;       (DQ in same format as SR)
  260. ;
  261. ;   An = Y:(R6) = si.ff ffff | ffff ffff | 0000 0000 (16TC)
  262. ;       (Bn in same format as An)
  263. ;
  264. ; Output:
  265. ;   WAn = X:(R1) = siii iiii | iiii iii.f | 0000 0000  (16TC)
  266. ;       (WBn in same format as WAn)
  267. ;
  268. ;**************************************************************************
  269.  
  270.         MOVE    #CONST,R0           ;Set pointer to FMULT constants
  271.         MOVE    #0,Y1
  272.         DO      #8,ACCUM_T          ;Execute mult 8 times
  273.  
  274. ; 1. Convert 16TC An to 13SM AnMAG
  275.         MOVE    X:(R0)+,X1  Y:(R6),A    ;Get An and mask KF1
  276.         AND     X1,A    X:(R0)+,X1  ;Truncate An to 13 bits (An>>2),
  277.                                     ; get mask KF2
  278.         ABS     A       #$000D,R4   ;Find AnMAG, load
  279.                                     ; exponent bias (13) into R4
  280.         AND     X1,A    #<$7E,X1    ;Truncate any ovrflw, get mask
  281. ;   A1 = 0i.ff ffff | ffff ff00 | 0000 0000 (A2=A0=0)
  282.  
  283. ; 2. Convert 13SM AnMAG to 10FL (AnEXP and AnMANT)
  284.         JNE     <NORMAN_T           ;Test AnMAG
  285.         MOVE    #<$40,A             ;If AnMAG=0, set AnMANT=1<<5,
  286.         MOVE    #0,R4               ; and AnEXP=0
  287.         JMP     <CONTIN_T
  288. NORMAN_T    NORM    R4,A            ;If AnMAG!=0 do NORM iteration
  289.         NORM    R4,A                ; 12 times to find MSB
  290.         NORM    R4,A
  291.         NORM    R4,A
  292.         NORM    R4,A
  293.         NORM    R4,A
  294.         NORM    R4,A
  295.         NORM    R4,A
  296.         NORM    R4,A
  297.         NORM    R4,A
  298.         NORM    R4,A
  299.         NORM    R4,A
  300. ;   A1 = 01?? ???? | ???? ??00 | 0000 0000 = AnMANT
  301. ;   R4 = 0000 0000 | 0000 eeee = AnEXP
  302. CONTIN_T    AND     X1,A    R4,B    ;Truncate AnMANT to 6 bits,
  303.                                     ; move AnEXP to B
  304. ;   A1 = 01mm mmm0 | 0000 0000 | 0000 0000 (A2=A0=0)
  305. ;   B1 = 0000 0000 | 0000 0000 | 0000 eeee (B2=B0=0)
  306.  
  307. ; 3. Add SRnEXP to AnEXP to get WAnEXP (5-bits)
  308.         MOVE    X:(R2)+,X1  A,Y0    ;Get SRnEXP
  309.         ADD     X1,B    X:(R2)+,X1  ;Find WAnEXP=SRnEXP+AnEXP,
  310.                                     ; get SRnMANT 
  311. ;   B1 = 0000 0000 | 0000 0000 | 000e eeee (B2=B0=0)
  312.  
  313. ; 4. Multiply SRnMANT with AnMANT, add '48', and truncate
  314. ;       to 8-bits to get WAnMANT
  315. ;   Y0 = 01mm mmm0 | 0000 0000 | 0000 0000
  316. ;   X1 = 01mm mmm0 | 0000 0000 | 0000 0000
  317.         MPY     Y0,X1,A     X:(R0)+,X0  ;Find WAnMANT, get '48' (KF3)
  318. ;   A1 = 0mmm mmmm | mmmm m000 | 0000 0000 (A2=A0=0)
  319. ;   X0 = 0000 0001 | 1000 0000 | 0000 0000 = '48'
  320.         ADD     X0,A        X:(R0)+,X0  ;Add '48' to WAnMANT, get mask KF4
  321.         AND     X0,A        X:(R0)+,X0  ;Truncate WAnMANT to 8 bits,
  322.                                         ; get '26' (KF5)
  323. ;   A1 = 0mmm mmmm | m000 0000 | 0000 0000 (A2=A0=0)
  324.  
  325. ; 5. Convert 13FL (WAnEXP & WAnMANT) to 15SM WAnMAG
  326. ;   X0 = 0000 0000 | 0000 0000 | 0001 1010 = '26'
  327. ;   B1 = 0000 0000 | 0000 0000 | 000e eeee (B2=B0=0) 
  328.         SUB     X0,B    X:(R0)+,X0  ;Find shift offset (WAnEXP-26),
  329.                                     ; get mask KF6
  330.         JEQ     <TRUNC_T            ;If offset=26 no shift
  331.         JMI     <RIGHT_T            ;If offset<26 do right shift
  332.                                     ;Else offset>26, do left shift
  333.         REP     B1                  ;Offset>26, shift WAnMANT
  334.         LSL     A                   ; left up to 4 times
  335.         JMP     <TRUNC_T
  336. RIGHT_T ABS     B       #>$0F,Y0    ;Find |offset|, get '15'
  337.         CMP     Y0,B    B1,N5       ;Compare |offset| to '15',
  338.                                     ; load offset for shift
  339.         TGE     Y1,A                ;If |offset|>=15 WAnMAG=0
  340.         MOVE    A1,X1               ;Move WAnMANT for shift
  341.         MOVE    Y:(R5+N5),Y0        ;Lookup shift constant
  342.         MPY     Y0,X1,A             ;Shift WAnMANT right up to 14 times
  343. ;   A1 = ?mmm mmmm | mmmm mmmm | ???? ???? (A2=A0=0)
  344. TRUNC_T AND     X0,A    X:(R2)+,X1  Y:(R6)+,B   ;Truncate WAnMAG to 15 bits,
  345.                                     ; get SRnS & AnS
  346. ;   A1 = 0iii iiii | iiii iii.f | 0000 0000 (A2=A0=0)
  347.         NEG     A   A1,X0           ;Find -WAnMAG, save WAnMAG
  348.  
  349. ; 6. XOR AnS with SRnS to find WAnS
  350. ;   B1 = sXXX XXXX | XXXX XXXX | 0000 0000 (B2=sign ext, B0=0)
  351. ;   X1 = sXXX XXXX | XXXX XXXX | 0000 0000
  352.         EOR     X1,B    #CONST,R0   ;Find WAnS (in MSB of B),
  353.                                     ; update pointer to constants
  354.  
  355. ; 7. Convert 16SM (WAnMAG & WAnS) to 16TC WAn
  356.         TPL     X0,A                ;If WAnS=0 use WAnMAG, else use -WAnMAG
  357. ;   A1 = siii iiii | iiii iii.f | 0000 0000  (A2=sign ext, A0=0)
  358.         MOVE    A1,X:(R1)+          ;Save WAn
  359.  
  360. ;**************************************************************************
  361. ;       ACCUM
  362. ;
  363. ; Add predictor outputs to form the partial signal estimate
  364. ;   and the signal estimate
  365. ;
  366. ; SEZ(k) = [B1(k-1) * DQ(k-1)] + ... + [B6(k-1) * DQ(k-6)]
  367. ;        = WB1 + WB2 + ... + WB6
  368. ;
  369. ; SE(k) = SEZ(k) + [A1(k-1) * SR(k-1)] + [A2(k-1) * SR(k-2)]
  370. ;       = SEZ + WA1 + WA2
  371. ;
  372. ; Inputs:
  373. ;   WBn & WAn = X:(R1) = siii iiii | iiii iii.f | 0000 0000  (16TC)
  374. ;
  375. ; Outputs:
  376. ;   SEZ = siii iiii | iiii iii.0 | 0000 0000  (15TC)
  377. ;   SE = siii iiii | iiii iii.0 | 0000 0000  (15TC)
  378. ;
  379. ;**************************************************************************
  380.  
  381. ACCUM_T MOVE    X:(R1)+,A           ;Get WB1
  382.         MOVE    X:(R1)+,X0          ;Get WB2
  383.         ADD     X0,A    X:(R1)+,X0  ;Accumulate WB1&WB2, get WB3
  384.         ADD     X0,A    X:(R1)+,X0  ;Accumulate WB3, get WB4
  385.         ADD     X0,A    X:(R1)+,X0  ;Accumulate WB4, get WB5
  386.         ADD     X0,A    X:(R1)+,X0  ;Accumulate WB5, get WB6
  387.         ADD     X0,A    X:(R1)+,X0  ;Accumulate WB6 to get SEZI, get WA1
  388.         TFR     A,B     Y:(R7)+,X1  ;Copy SEZI, get mask K1
  389.         AND     X1,B    X:AP_T,Y0   ;Truncate SEZI, get AP
  390.         ADD     X0,A    X:(R1)+,X0  ;Accumulate WA1, get WA2
  391.         ADD     X0,A    B1,Y:SEZ_T  ;Accumulate WA2 to get SEI, save SEZ
  392.         AND     X1,A    #<$20,X0    ;Truncate SEI, get '1'
  393.         TFR     Y0,A    A1,Y:SE_T   ;Move AP, save SE
  394.  
  395. ;**************************************************************************
  396. ;       LIMA
  397. ;
  398. ; Limit speed control parameter
  399. ;
  400. ; AL(k) = 1        if AP(k-1) > 1
  401. ;       = AP(k-1)  if AP(k-1) <= 1
  402. ;
  403. ; Inputs:
  404. ;   AP = 0ii.f ffff | fff0 0000 | 0000 0000  (10SM)
  405. ;
  406. ; Outputs:
  407. ;   AL = 0i.ff ffff | 0000 0000 | 0000 0000  (7SM)
  408. ;
  409. ;**************************************************************************
  410.  
  411.         CMP     X0,A    Y:YL_T,B    ;Test AP, get YL
  412.         TGT     X0,A                ;If AP>'1' set AL='1'
  413.         LSL     A       #<$7F,X0    ;Shift to align radix pt., get mask
  414.         AND     X0,A    Y:(R7)+,X0  ;Truncate AL (AP>>2), get mask K2
  415.  
  416. ;**************************************************************************
  417. ;       MIX
  418. ;
  419. ; Form linear combination of fast and slow quantizer
  420. ;   scale factors
  421. ;
  422. ; Y(k) = AL(k) * YU(k-1) + [1 - AL(k)] * YL(k-1)
  423. ;
  424. ; Inputs:
  425. ;   YL = 0iii i.fff | ffff ffff | ffff 0000  (19SM)
  426. ;   AL = 0i.ff ffff | 0000 0000 | 0000 0000  (7SM)
  427. ;   YU = 0iii i.fff | ffff ff00 | 0000 0000  (13SM)
  428. ;
  429. ; Outputs:
  430. ;   Y = 0iii i.fff | ffff ff00 | 0000 0000  (13SM)
  431. ;
  432. ;**************************************************************************
  433.  
  434.         AND     X0,B    A,X0    Y:YU_T,A    ;Truncate YL (YL>>6), get YU
  435.         SUB     B,A     B,Y1    X0,X:AL_T   ;Find DIF=YU-YL, save YL, get AL
  436.         ABS     A       A,B         ;Find DIFM=|DIF|, save DIFS
  437.         MOVE    A1,Y0
  438.         MPY     X0,Y0,A     Y:(R7)+,X0  ;Find DIFM*AL, get mask K3
  439.         AND     X0,A                ;Truncate to find PRODM=(DIFM*AL)>>6
  440.         NEG     A   A1,X0           ;Find -PRODM, save PRODM
  441.         TST     B                   ;Check DIFS
  442.         TPL     X0,A                ;If DIFS=0 PROD=PRODM,
  443.                                     ; else PROD=-PRODM
  444.         ASL     A   Y1,B            ;Line up radix point
  445.         ADD     Y1,A                ;Find Y=PROD+(YL>>6)
  446.         MOVE    A,X:Y_T             ;Save Y
  447.  
  448. ;**************************************************************************
  449. ;
  450. ; Input PCM data (S) here. For simulation purposes the Input 
  451. ; Word from File subroutine on the 56001 ADS board is used.
  452. ;
  453. ;**************************************************************************
  454.  
  455.         MOVE    #1,X0               ;Input PCM word (S)
  456.         JSR     $E002
  457.  
  458. ;**************************************************************************
  459. ;       EXPAND
  460. ;
  461. ; Convert A-law or mu-law PCM to uniform PCM (according to
  462. ;   Recommendation G.711). For further details see Motorola
  463. ;   application bulletin "Logarithmic/Linear Conversion
  464. ;   Routines for DSP56000/1".
  465. ;
  466. ; Input:
  467. ;   S = psss qqqq | 0000 0000 | 0000 0000 (PCM log format)
  468. ;
  469. ; Output:
  470. ;   SL = siii iiii | iiii ii.00 | 0000 0000  (14TC)
  471. ;
  472. ;**************************************************************************
  473.  
  474.         MOVE    A,X0    Y:(R7)+,Y1  ;Get shift constant K4
  475.         MPY     X0,Y1,A     Y:(R7)+,X1  ;Shift S to 8 lsb's of A1, get K5
  476.         AND     X1,A    Y:SE_T,B    ;Mask off sign of S, get SE
  477.         ASR     B       A1,N3       ;sign extend SE, load |S| as offset
  478.         CMPM    Y1,A                ;Check sign of S
  479.         MOVE    X:(R3+N3),A         ;Lookup |SL| from ROM table
  480.         JGE     <SUBTA_T            ;If S=0, SL=|SL|
  481.         NEG     A                   ;If S=1, SL=-|SL|
  482.  
  483. ;**************************************************************************
  484. ;       SUBTA
  485. ;
  486. ; Compute difference signal by subtracting signal estimate
  487. ;       from input signal
  488. ;
  489. ;   D(k) = SL(k) - SE(k)
  490. ;
  491. ; Inputs:
  492. ;   SL = siii iiii | iiii ii.00 | 0000 0000  (14TC) 
  493. ;   SE = siii iiii | iiii iii.0 | 0000 0000  (15TC)
  494. ;
  495. ; Output:
  496. ;   D = siii iiii | iiii iiii. | 0000 0000  (16TC)
  497. ;**************************************************************************
  498.  
  499. SUBTA_T ASR     A       Y:(R7)+,X1  ;Sign extend SL, get mask K6
  500.         ASR     A       #$000E,R0   ;Sign extend SE again, get exp bias (14)
  501.         SUB     B,A     X:Y_T,B     ;Find D=SL-SE, get Y
  502.  
  503. ;**************************************************************************
  504. ;       LOG
  505. ;
  506. ; Convert difference signal from the linear to the log
  507. ;   domain
  508. ;
  509. ; Input:
  510. ;   D = siii iiii | iiii iiii. | 0000 0000  (16TC)
  511. ;
  512. ; Outputs:
  513. ;   DL = 0iii i.fff | ffff 0000 | 0000 0000  (11SM)
  514. ;   DS = sXXX XXXX | XXXX XXXX | 0000 0000  (1TC)
  515. ;
  516. ;**************************************************************************
  517.  
  518.         ABS     A   A,Y1            ;Find DQM=|D|, save DS to Y1
  519.         JNE     <NORMEXP_T          ;Check for DQM=0
  520.         CLR     A       (R7)+       ;If DQM=0 set DL=0,
  521.         MOVE    Y:(R7),X0           ; get mask K8,
  522.         JMP     <SUBTB_T            ; and continue
  523. NORMEXP_T   NORM    R0,A            ;If DQM!=0, do norm iteration
  524.         NORM    R0,A                ; 14 times to find MSB of DQM
  525.         NORM    R0,A
  526.         NORM    R0,A
  527.         NORM    R0,A
  528.         NORM    R0,A
  529.         NORM    R0,A
  530.         NORM    R0,A
  531.         NORM    R0,A
  532.         NORM    R0,A
  533.         NORM    R0,A
  534.         NORM    R0,A
  535.         NORM    R0,A
  536.         NORM    R0,A
  537. ;   A1 = 01?? ???? | ???? ???? | 0000 0000 = normalized DQM  (A2=A0=0)
  538. ;   R0 = 0000 0000 | 0000 eeee = exponent of normalized DQM
  539.  
  540. ;   Get rid of leading "1" in normalized DQM
  541. ;   Truncate mantissa to 7 bits and combine with exponent
  542.         AND     X1,A    Y:LSHFT-19,X0   ;Truncate MANT, get EXP shift
  543. ;   A1 = 00mm mmmm | m000 0000 | 0000 0000 (A2=A0=0)
  544.         MOVE    R0,X1               ;Move EXP to X1
  545.         MPY     X0,X1,A     A,X1    Y:(R7)+,Y0 ;Shift EXP<<19, save MANT to X1,
  546.                                     ; get mask K7
  547.         MOVE    A0,A                ;Move EXP to A1
  548. ;   A1 = 0eee e000 | 0000 0000 | 0000 0000 (A2=A0=0)
  549.         MAC     Y0,X1,A     Y:(R7),X0   ;Shift MANT>>3 & combine with EXP,
  550.                                         ; get mask K8
  551. ;   A1 = 0eee e.mmm | mmmm 0000 | 0000 0000  (A2=A0=0)
  552. ;      = 0iii i.fff | ffff 0000 | 0000 0000  (A2=A0=0)
  553.  
  554. ;**************************************************************************
  555. ;       SUBTB
  556. ;
  557. ; Scale log version of difference signal by subtracting
  558. ;   scale factor
  559. ;
  560. ; DLN = DL - Y
  561. ;
  562. ; Inputs:
  563. ;   DL = 0iii i.fff | ffff 0000 | 0000 0000  (11SM)
  564. ;   Y = 0iii i.fff | ffff ff00 | 0000 0000  (13SM)
  565. ;
  566. ; Output:
  567. ;   DLN = siii i.fff | ffff 0000 | 0000 0000 (12TC)
  568. ;
  569. ;**************************************************************************
  570.  
  571. SUBTB_T AND     X0,B    #QUANTAB,R0     ;Truncate Y to 11 bits (Y>>2),
  572.                                         ; get quantization table base
  573.         SUB     B,A     #>QUANTAB+2,X1  ;Find DLN=DL-Y,
  574.                                         ; get offset for quan. conversion
  575.  
  576. ;**************************************************************************
  577. ;       QUAN
  578. ;
  579. ; Quantize difference signal in log domain
  580. ;
  581. ;    log2|D(k)| - Y(k) | |I(k)|
  582. ;    ------------------+--------
  583. ;      [3.12, + inf)   |   7
  584. ;      [2.72, 3.12)    |   6
  585. ;      [2.34, 2.72)    |   5
  586. ;      [1.91, 2.34)    |   4
  587. ;      [1.38, 1.91)    |   3
  588. ;      [0.62, 1.38)    |   2
  589. ;      [-0.98, 0.62)   |   1
  590. ;      (- inf, -0.98)  |   0
  591. ;
  592. ; Inputs:
  593. ;   DLN = siii i.fff | ffff 0000 | 0000 0000 (12TC)
  594. ;   DS = sXXX XXXX | XXXX XXXX | 0000 0000  (1TC)
  595. ;
  596. ; Output:
  597. ;   I = siii 0000 | 0000 0000 | 0000 0000 (ADPCM format)
  598. ;
  599. ;**************************************************************************
  600.  
  601.         MOVE    X:(R0)+,X0          ;Get quan table value
  602. TSTDLN_T    CMP     X0,A    X:(R0)+,X0  ;Compare to DLN
  603.         JGE     <TSTDLN_T           ;If value<DLN try next range
  604.         MOVE    R0,A                ;When range found...
  605.                                     ; subtract pointer from
  606.         SUB     X1,A    Y:LSHFT-20,X0   ; base to get IMAG=|I|  
  607. ;   A1 = 0000 0000 | 0000 0000 | 0000 0iii (A2=A0=0)
  608.         MOVE    A1,X1
  609.         MPY     X0,X1,A     Y1,B    ;Shift IMAG <<20, result is
  610.                                     ; in A0, move DS (from LOG) into B
  611.         MOVE    A0,A
  612. ;   A1 = 0iii 0000 | 0000 0000 | 0000 0000 (A2=A0=0)
  613.         MOVE    A1,X:IMAG           ;Save IMAG
  614.         TST     A       #<$F0,X0    ;Check IMAG, get invert mask
  615.         JEQ     <INVERT_T           ;If IMAG=0 invert bits
  616.         TST     B                   ;If IMAG!=0, check DS
  617.         JPL     <IOUT_T             ;If DS=1 don't invert IMAG
  618. INVERT_T    EOR     X0,A            ;If DS=0 or IMAG=0,
  619.                                     ; invert IMAG
  620. IOUT_T  MOVE    A1,A                ;Adjust sign extension
  621.         
  622. ;**************************************************************************
  623. ;
  624. ; Output ADPCM data (I) here. For simulation purposes the Output 
  625. ; Word to File subroutine on the 56001 ADS board is used.
  626. ;
  627. ;**************************************************************************
  628.  
  629.         MOVE    #1,X0               ;Output ADPCM word (I)
  630.         JSR     $E004
  631.  
  632. ;**************************************************************************
  633. ;       RECONST
  634. ;
  635. ; Reconstruct quantized difference signal in the log domain
  636. ;
  637. ;     |I(k)| | log2|DQ(k)| - Y(k)
  638. ;    --------+-------------------
  639. ;       7    |      3.32
  640. ;       6    |      2.91
  641. ;       5    |      2.52
  642. ;       4    |      2.13
  643. ;       3    |      1.66
  644. ;       2    |      1.05
  645. ;       1    |      0.031
  646. ;       0    |      - inf
  647. ;
  648. ; Inputs:
  649. ;   I = iiii 0000 | 0000 0000 | 0000 0000  (ADPCM format)
  650. ;
  651. ; Output:
  652. ;   DQLN = siii i.fff | ffff 0000 | 0000 0000  (12TC)
  653. ;   DQS = sXXX 0000 | 0000 0000 | 0000 0000  (1TC)
  654. ;
  655. ;**************************************************************************
  656.  
  657.         MOVE    A,Y1    A,X:I_T     ;Save DQS (sign of I) to Y1
  658.         MOVE    #IQUANTAB,R4        ;Set lookup table base
  659. ;   X1 = 0000 0000 | 0000 0000 | 0000 0iii = |I| (from QUAN)
  660.         MOVE    X1,N4               ;Load |I| as offset
  661.         MOVE    X:Y_T,B             ; into IQUAN table, get Y
  662.         MOVE    X:(R4+N4),A         ;Lookup DQLN
  663.  
  664. ;**************************************************************************
  665. ;       ADDA
  666. ;
  667. ; Add scale factor to log version of quantized difference
  668. ;   signal
  669. ;
  670. ; DQL = DQLN + Y
  671. ;
  672. ; Inputs:
  673. ;   Y = 0iii i.fff | ffff ff00 | 0000 0000  (13SM)
  674. ;   DQLN = siii i.fff | ffff 0000 | 0000 0000  (12TC)
  675. ;
  676. ; Output:
  677. ;   DQL = siii i.fff | ffff 0000 | 0000 0000  (12TC)
  678. ;
  679. ;**************************************************************************
  680.  
  681.         MOVE    Y:(R7)+,Y0          ;Get mask K8 for ADDA
  682.         AND     Y0,B    Y:(R7)+,X0  ;Truncate Y to 11 bits (Y<<2),
  683.                                     ; get mask K9
  684.         ADD     B,A     #<$08,X1    ;Find DQL=DQLN+(Y<<2), get '1'
  685.    
  686. ;**************************************************************************
  687. ;       ANTILOG
  688. ;
  689. ; Convert quantized difference signal from log to linear
  690. ;   domain
  691. ;
  692. ; Input:
  693. ;   DQL = siii i.fff | ffff 0000 | 0000 0000  (12TC)
  694. ;   DQS = sXXX 0000 | 0000 0000 | 0000 0000  (1TC)
  695. ;
  696. ; Outputs:
  697. ;   DQ = siii iiii | iiii iii.0 | 0000 0000  (15SM)
  698. ;
  699. ;**************************************************************************
  700.  
  701.         JPL     <CONVLOG_T          ;If DQL>=0 (DS=0) convert DQL,
  702.                                     ; else DQL<0 (DS=1), set |DQ|=0
  703.         TFR     Y1,A    #<$80,X0    ;Get DQS (MSB of I), get mask
  704.         AND     X0,A    #0,B        ;Mask off DQS, set |DQ|=0
  705. ;   A1 = s000 0000 | 0000 0000 | 0000 0000  (A2=sign ext, A0=0)
  706.         MOVE    B1,Y:DQMAG          ;Save DQMAG=|DQ|
  707.         MOVE    (R7)+               ;Adjust constant pointer
  708.         MOVE    (R7)+
  709.         JMP     <SAVEDQ_T
  710.  
  711. CONVLOG_T   AND     X0,A    A,B     ;Find fractional part (DMN),
  712.                                     ; save DS
  713. ;   A1 = 0000 0.fff | ffff 0000 | 0000 0000  (A2=A0=0)
  714.         OR      X1,A    #<$78,X0    ;Add implied '1' to DMN to
  715.                                     ; find DQT, get integer mask
  716. ;   A1 = 0000 1.fff | ffff 0000 | 0000 0000  (A2=A0=0)
  717.         AND     X0,B    Y:RSHFT+19,Y0   ;Find integer part (DEX),
  718.                                     ; get shift constant
  719. ;   B1 = 0iii i.000 | 0000 0000 | 0000 0000  (B2=B0=0)
  720.         MOVE    B1,X0
  721.         MPY     X0,Y0,B     Y:(R7)+,X0  ;Shift DEX>>19, get '10' (K10)
  722. ;   A1 = 0000 1.fff | ffff 0000 | 0000 0000  (A2=A0=0)
  723. ;   B1 = 0000 0000 | 0000 0000 | 0000 iiii.  (B2=B0=0)
  724.         SUB     X0,B    Y:(R7)+,X0  ;Find DQT shift=DEX-'10',
  725.                                     ; get mask K11
  726.         JEQ     <TRUNCDQM_T         ;If DEX=10, no shift
  727.         JLT     <SHFRDQ_T           ;If DEX<10, shift right
  728.         REP     B1                  ;Else shift DQT left
  729.         LSL     A                   ; up to 4 times
  730.         JMP     <TRUNCDQM_T
  731.  
  732. SHFRDQ_T    NEG     B               ;Find 10-DEX
  733.         MOVE    B1,N5               ;Use 10-DEX for shift lookup
  734.         MOVE    A1,Y0
  735.         MOVE    Y:(R5+N5),X1        ;Lookup shift constant
  736.         MPY     X1,Y0,A             ;Shift DQT right up to 9 times
  737. TRUNCDQM_T  AND     X0,A    #<$80,B ;Truncate to find DQMAG=|DQ|,
  738.                                     ; get sign mask
  739. ;   A1 = 0iii iiii | iiii iii.0 | 0000 0000  (A2=A0=0)
  740.         AND     Y1,B    A1,Y:DQMAG  ;Mask off DQS, save DQMAG           
  741. ;   B1 = s000 0000 | 0000 0000 | 0000 0000  (B2=?, B0=0)
  742.         MOVE    B1,X0
  743.         OR      X0,A                ;Add DQS to DQMAG to get DQ
  744. ;   A1 = siii iiii | iiii iii.0 | 0000 0000  (A2=?, A0=0)
  745. SAVEDQ_T    MOVE    A1,X:DQ_T       ;Save DQ
  746.  
  747. ;**************************************************************************
  748. ;       TRANS
  749. ;
  750. ; Transition detector
  751. ;
  752. ; TR(k) = 1 if TD(k)=1 and |DQ(k)|> 24 x 2**(YL(k))
  753. ;         0 otherwise
  754. ;
  755. ; Inputs:
  756. ;   TD = i000 0000 | 0000 0000 | 0000 0000  (1TC)
  757. ;   YL = 0iii i.fff | ffff ffff | ffff 0000  (19SM)
  758. ;   DQ = siii iiii | iiii iii.0 | 0000 0000  (15SM)
  759. ;
  760. ; Output:
  761. ;   TR = i000 0000 | 0000 0000 | 0000 0000  (1TC)
  762. ;
  763. ;**************************************************************************
  764.  
  765.         MOVE    Y:TD_T,A            ;Get TD
  766.         TST     A   #0,A            ;Check TD, set TR=0
  767.         JEQ     <SAVETR_T           ;If TD=0 save TR=0
  768.                                     ; else test DQ and YL
  769.         MOVE    Y:YL_T,A            ;Get YL
  770.         TFR     A,B     Y:(R7)+,X0  ;Save YL, get mask K12
  771.         AND     X0,A    #<$08,X0    ;Find YLFRAC (YL>>10), get '1'
  772.         OR      X0,A    B,X1    Y:(R7)+,Y1  ;Add implied '1' to YLFRAC,
  773.                                     ; get mask K13
  774.         MPY     Y1,X1,B     Y:(R7)+,X0  ;Find YLINT=YL>>15, get '8' (K14)
  775.         MOVE    B1,B                ;Adjust sign extension
  776.         CMP     X0,B    Y:(R7)+,X0  ;Compare YLINT to '8', get '5' (K15)
  777.         JGT     <MAXTHR_T           ;If YLINT>8 set maximum THR2
  778.         SUB     X0,B                ;Find YLINT-5
  779.         JEQ     <SETDQTHR_T         ;If YLINT=5 don't shift
  780.         JLT     <RSHFT_T            ;If YLINT<5 shift right
  781.  
  782.         REP     B1                  ;Else shift YLFRAC left
  783.         LSL     A                   ; up to 3 times to get THR1
  784.         JMP     <SETDQTHR_T
  785.  
  786. MAXTHR_T    MOVE    #<$7C,A         ;Set maximum THR2 (31<<9)
  787.         JMP     <SETDQTHR_T
  788.  
  789. RSHFT_T NEG     B                   ;Find 5-YLINT
  790.         MOVE    B1,N5               ;Use 5-YLINT for shift lookup
  791.         MOVE    A1,X0
  792.         MOVE    Y:(R5+N5),X1        ;Lookup shift constant
  793.         MPY     X0,X1,A             ;Shift YLFRAC right up to ? times
  794.                                     ; to get THR1
  795. SETDQTHR_T  TFR     A,B     Y:(R7)+,X0  ;Get mask K16
  796.         LSR     B                   ;Find THR2>>1
  797.         AND     X0,B                ;Truncate THR2>>1
  798.         ADD     B,A     #0,X1       ;Find THR2+(THR2>>1)
  799.         LSR     A                   ;Find (THR2+(THR2>>1)>>1
  800.         AND     X0,A    Y:DQMAG,X0  ;Truncate to find DQTHR, get DQMAG
  801.         CMP     X0,A    #<$80,A     ;Compare DQMAG to DQTHR, set TR=1
  802.         TGT     X1,A                ;If DQMAG>DQTHR leave TR=1,
  803.                                     ; else DQMAG<=DQTHR, set TR=0
  804. SAVETR_T    MOVE    A1,Y:TR_T       ;Save TR
  805.  
  806. ;**************************************************************************
  807. ;       ADDB
  808. ;
  809. ; Add quantized difference signal and signal estimate
  810. ;   to form reconstructed signal
  811. ;
  812. ; SR(k-n) = SE(k-n) + DQ(k-n)
  813. ;
  814. ; Inputs:
  815. ;   DQ = siii iiii | iiii iii.0 | 0000 0000  (15SM)
  816. ;   SE = siii iiii | iiii iii.0 | 0000 0000  (15TC)
  817. ;
  818. ; Output:
  819. ;   SR = siii iiii | iiii iiii. | 0000 0000  (16TC)
  820. ;
  821. ;**************************************************************************
  822.  
  823.         MOVE    Y:SE_T,B            ;Get SE
  824.         ASR     B   X:DQ_T,A        ;Sign extend SE to get SEI, get DQS
  825.         TST     A       Y:DQMAG,A   ;Check DQS, get DQMAG
  826.         JPL     <SHFTDQ_T           ;If DQS=0 continue
  827.         NEG     A                   ;Convert DQ to 2's comp
  828. SHFTDQ_T    ASR     A               ;Sign extend DQ to get DQI
  829.         ADD     A,B     #CONST17,R7 ;Find SR=DQ+SE, update const pointer
  830.  
  831. ;**************************************************************************
  832. ;       ADDC
  833. ;
  834. ; Obtain sign of addition of the quantized difference
  835. ;   signal and the partial signal estimate
  836. ;
  837. ; P(k) = DQ(k) + SEZ(k)
  838. ; PK0 = sign of P(k)
  839. ;
  840. ; Inputs:
  841. ;   DQ = siii iiii | iiii iii.0 | 0000 0000  (15SM)
  842. ;   SEZ = siii iiii | iiii iii.0 | 0000 0000 (15TC)
  843. ;
  844. ; Output:
  845. ;   PK0 = sXXX XXXX | XXXX XXXX | 0000 0000  (1TC)
  846. ;   SIGPK = i000 0000 | 0000 0000 | 0000 0000  (1TC)
  847. ;
  848. ;**************************************************************************
  849.  
  850.         MOVE    B1,Y:SR_T           ;Save SR
  851.         MOVE    Y:SEZ_T,B           ;Get SEZ
  852.         ASR     B                   ;Sign extend SEZ to SEZI
  853.         ADD     B,A     #0,B        ;Find DQSEZ=DQ+SEZ,
  854.                                     ; set SIGPK=0
  855.         TST     A   #<$80,X0        ;Check DQSEZ, get '1'
  856.         TEQ     X0,B                ;If DQSEZ=0, SIGPK=1,
  857.                                     ; else SIGPK=0
  858.  
  859.         MOVE    Y:PK1_T,X0
  860.         MOVE    X0,Y:PK2_T          ;Delay previous PK1
  861.         MOVE    Y:PK0_T,X0
  862.         MOVE    X0,Y:PK1_T          ;Delay previous PK0
  863.         MOVE    A1,Y:PK0_T          ;Save new PK0
  864.         MOVE    B1,Y:SIGPK_T        ;Save SIGPK
  865.         EOR     X0,A    Y:PK2_T,X0  ;Find PKS1=PK0**PK1
  866.                                     ; for UPA1 & UPA2
  867.         MOVE    A1,X:PKS1           ;Save PKS1
  868.         MOVE    Y:PK0_T,A
  869.         EOR     X0,A    #3,N2       ;Find PKS2=PK0**PK2 for UPA2
  870.         MOVE    A1,X:PKS2           ;Save PKS2
  871.         MOVE    (R2)+               ;Adjust data buffer pointer so
  872.         MOVE    (R2)+               ; that R2 points to DQ1S
  873.  
  874. ;**************************************************************************
  875. ;       XOR
  876. ;
  877. ; Find one bit "exclusive or" of the sign of difference
  878. ;   signal and the sign of delayed difference signal.
  879. ;
  880. ; Un = sgn[DQ(k)] XOR sgn[DQ(k-n)]
  881. ;
  882. ; Inputs:
  883. ;   DQ = siii iiii | iiii iii.0 | 0000 0000 (15SM)
  884. ;   DQnS = X:(R2+n) sXXX XXXX | XXXX XXXX | 0000 0000
  885. ;
  886. ; Outputs:
  887. ;   Un = sXXX XXXX | XXXX XXXX | 0000 0000 (1TC)
  888. ;
  889. ;**************************************************************************
  890. ;**************************************************************************
  891. ;       UPB
  892. ;
  893. ; Update the coefficients of the sixth order predictor
  894. ;
  895. ; Bn(k) = [1-(2**-8)] * Bn(k-1)
  896. ;           + (2**-7) * sgn[DQ(k)] * sgn[DQ(k-n)]
  897. ;
  898. ; Inputs:
  899. ;   Bn = Y:(R6+n) = si.ff ffff | ffff ffff | 0000 0000 (16TC)
  900. ;   DQ = siii iiii | iiii iii.0 | 0000 0000 (15SM)
  901. ;   Un = sXXX XXXX | XXXX XXXX | 0000 0000 (1TC)
  902. ;
  903. ; Outputs:
  904. ;   BnP = Y:(R6+n) = si.ff ffff | ffff ffff | 0000 0000 (16TC)
  905. ;
  906. ;**************************************************************************
  907.  
  908.         MOVE    Y:DQMAG,A           ;Get DQMAG
  909.         TST     A   X:DQ_T,Y0       ;Check DQMAG, get DQS
  910.         JNE     <XORUPB_T           ;If DQMAG!=0 use section with XOR,
  911.                                     ; else use section with no XOR
  912.                                     ; (because UGBn=0 if DQMAG=0)
  913.  
  914. ; UPB without XOR
  915.         MOVE    Y:RSHFT+8,X1        ;Get shift constant
  916.         MOVE    (R7)+               ;Adjust constant pointer
  917.         MOVE    (R7)+
  918.         MOVE    Y:(R7)+,X0          ;Get mask K19
  919.         DO      #6,ENDLOOP_T        ;Do UPB for B1-B6
  920.         MOVE    X:(R2)+N2,A     Y:(R6),Y1   ;Get Bn (& DQnS but don't use)
  921.         MPY     X1,Y1,A             ;Find Bn>>8
  922.         AND     X0,A                ;Truncate (Bn>>8)
  923.         NEG     A                   ;Find UBn=ULBn=-(Bn>>8)
  924.         ADD     Y1,A                ;Find BnP=Bn+UBn
  925.         MOVE    A1,Y:(R6)+          ;Store BnP to Bn
  926. ENDLOOP_T   JMP     <UPA2_T
  927.  
  928. ; UPB with XOR
  929. XORUPB_T    MOVE    Y:(R7)+,X0      ;Get +gain (K17)
  930.         DO      #6,UPTR_T           ;Do UPB and XOR for B1-B6
  931.         MOVE    X:(R2)+N2,A     Y:(R6),Y1   ;Get Bn & DQnS
  932.         EOR     Y0,A    Y:(R7)+,X1  ;Find Un=DQS**DQnS (XOR),
  933.                                     ; get -gain (K18)
  934.         TPL     X0,A                ;If Un=0 set UGBn=+gain
  935.         TMI     X1,A                ;If Un=1 set UGBn=-gain
  936.         MOVE    Y:RSHFT+8,X1        ;Get shift constant
  937.         MPY     X1,Y1,B     Y:(R7)-,X1  ;Shift Bn>>8, get mask K19
  938.         AND     X1,B                ;Truncate (Bn>>8)
  939.         NEG     B                   ;Find ULBn=-(Bn>>8)
  940.         ADD     B,A                 ;Find UBn=UGBn+ULBn
  941.         ADD     Y1,A                ;Find BnP=Bn+UBn
  942.         MOVE    A1,Y:(R6)+          ;Store BnP to Bn
  943. UPTR_T  MOVE    (R7)+               ;Adjust constant pointer
  944.         MOVE    (R7)+
  945.  
  946. ;**************************************************************************
  947. ;       UPA2
  948. ;
  949. ; Update the A2 coefficient of the second order predictor.
  950. ;
  951. ; A2(k) = [1-(2**-7)] * A2(k-1)
  952. ;           + (2**-7) * { sgn[P(k)] * sgn[P(k-2)]
  953. ;               - F[A1(k-1)] * sgn[P(k)] * sgn[P(k-1)] }
  954. ;
  955. ; F[A1(k)] = 4 * A1       if |A1|<=(2**-1)
  956. ;          = 2 * sgn(A1)  if |A1|>(2**-1)
  957. ;
  958. ; Inputs:
  959. ;   A1 = Y:(R6) = si.ff ffff | ffff ffff | 0000 0000 (16TC)
  960. ;   A2 = Y:(R6+1) = si.ff ffff | ffff ffff | 0000 0000 (16TC)
  961. ;   SIGPK = i000 0000 | 0000 0000 | 0000 0000  (1TC)
  962. ;   PK0 = sXXX XXXX | XXXX XXXX | 0000 0000  (1TC)
  963. ;   PK1 = sXXX XXXX | XXXX XXXX | 0000 0000  (1TC)
  964. ;   PK2 = sXXX XXXX | XXXX XXXX | 0000 0000  (1TC)
  965. ;     (Note: PKS1 & PKS2 have been previously calculated)
  966. ;
  967. ; Outputs:
  968. ;   A2T = si.ff ffff | ffff ffff | 0000 0000 (16TC)
  969. ;
  970. ;**************************************************************************
  971.  
  972. UPA2_T  MOVE    X:PKS2,A            ;Get PKS2=PK0**PK2
  973.         TST     A   #<$10,Y0        ;Check PKS2, get '+1'
  974.         MOVE    #<$F0,Y1            ;Get '-1'
  975.         TPL     Y0,A                ;If PKS2=0, set UGA2A='+1'
  976.         TMI     Y1,A                ;If PKS2=1, set UGA2A='-1'
  977.         MOVE    A,X1    Y:(R6)+,A   ;Save UGA2A, get A1
  978.         MOVE    Y:(R7)+,Y0          ;Get '+1.99' (K20)
  979.         CMP     Y0,A    Y:(R7)+,Y1  ;Check A1, get '-1.99' (K21)
  980.         TGT     Y0,A                ;If A1>=1/2, set FA1='1.99'
  981.         CMP     Y1,A    X:PKS1,B    ;Check A1 again, get PKS1=PK0**PK1
  982.         TLT     Y1,A                ;If A1<=-1/2, set FA1='-1.99'
  983.         TST     B       #0,X0       ;Check PKS1
  984.         JMI     <FINDSUM_T          ;If PKS1=1, FA=FA1
  985.         NEG     A                   ; else PKS1=0, set FA=-FA1
  986. FINDSUM_T   ADD     X1,A    Y:RSHFT+5,Y1    ;Find UGA2B=UGA2A+FA,
  987.                                     ; get shift constant
  988.         MOVE    A,X1
  989.         MPY     X1,Y1,A     Y:(R7)+,X1  ;Find UGA2B>>7, get mask K22
  990.         AND     X1,A    Y:SIGPK_T,B ;Truncate UGA2, get SIGPK
  991.         TST     B   Y:(R6),Y0       ;Check SIGPK, get A2
  992.         TMI     X0,A                ;If SIGPK=1, set UGA2=0
  993.         MOVE    Y:RSHFT+7,X0        ;Get shift constant
  994.         MPY     Y0,X0,B             ;Find A2>>7
  995.         AND     X1,B                ;Truncate to find A2>>7
  996.         NEG     B       #<$D0,X0    ;Find ULA2=-(A2>>7), get A2LL
  997.         ADD     B,A     #<$30,X1    ;Find UA2=UGA2+ULA2, get A2UL
  998.         ADD     Y0,A    Y:(R7)+,Y1  ;Find A2T=A2+UA2, get -gain (K23)
  999.  
  1000. ;**************************************************************************
  1001. ;       LIMC
  1002. ;
  1003. ; Limit the A2 coefficient of the second order predictor.
  1004. ;
  1005. ;   |A2(k)| <= '0.75' 
  1006. ;
  1007. ; Inputs:
  1008. ;   A2T = si.ff ffff | ffff ffff | 0000 0000 (16TC)
  1009. ;
  1010. ; Outputs:
  1011. ;   A2P = Y:(R6) = si.ff ffff | ffff ffff | 0000 0000 (16TC)
  1012. ;
  1013. ;**************************************************************************
  1014.  
  1015.         CMP     X0,A    Y:(R7)+,Y0  ;Check A2P, get +gain (K24)
  1016.         TLT     X0,A                ;If A2P<-0.75, set A2P=-0.75
  1017.         CMP     X1,A    X:PKS1,B    ;Check A2P again, get PKS1=PK0**PK1
  1018.         TGT     X1,A                ;If A2P>0.75, set A2P=0.75
  1019.         MOVE    A,Y:A2P_T           ;Save A2P
  1020.         MOVE    A,Y:(R6)-           ;Save A2P to A2
  1021.  
  1022. ;**************************************************************************
  1023. ;       UPA1
  1024. ;
  1025. ; Update the A1 coefficient of the second order predictor.
  1026. ;
  1027. ; A1(k) = [1-(2**-8)] * A1(k-1)
  1028. ;           + 3 * (2**-8) * sgn[P(k)] * sgn[P(k-1)]
  1029. ;
  1030. ; Inputs:
  1031. ;   A1 = Y:(R6) = si.ff ffff | ffff ffff | 0000 0000 (16TC)
  1032. ;   SIGPK = Y:(R0) = i000 0000 | 0000 0000 | 0000 0000  (1TC)
  1033. ;   PK0 = sXXX XXXX | XXXX XXXX | 0000 0000  (1TC)
  1034. ;   PK1 = sXXX XXXX | XXXX XXXX | 0000 0000  (1TC)
  1035. ;     (Note: PKS1 has been previously calculated)
  1036. ;
  1037. ; Outputs:
  1038. ;   A1T = si.ff ffff | ffff ffff | 0000 0000 (16TC)
  1039. ;
  1040. ;**************************************************************************
  1041.  
  1042.         TST     B       Y:SIGPK_T,B ;Check PKS1, get SIGPK
  1043.         TPL     Y0,A                ;If PKS=0, set UGA1=+gain
  1044.         TMI     Y1,A                ;If PKS=1, set UGA1=-gain
  1045.         TST     B       #0,X0       ;Check SIGPK
  1046.         TMI     X0,A                ;If SIGPK=1, set UGA1=0
  1047.         MOVE    Y:(R6),X1           ;Get A1
  1048.         MOVE    Y:RSHFT+8,Y0        ;Get shift constant
  1049.         MPY     Y0,X1,B     Y:(R7)+,X0  ;Find A1>>8, get mask K25
  1050.         AND     X0,B                ;Truncate (A1>>8)
  1051.         NEG     B                   ;Find ULA1=-(A1>>8)
  1052.         ADD     B,A     #<$3C,B     ;Find UA1=UGA1+ULA1,
  1053.                                     ; get OME='1-(2**-4)'
  1054.         ADD     X1,A    Y:A2P_T,X0  ;Find A1T=A1+UA1, get A2P
  1055.  
  1056. ;**************************************************************************
  1057. ;       LIMD
  1058. ;
  1059. ; Limit the A1 coefficient of the second order predictor.
  1060. ;
  1061. ;   |A1(k)| <= [1-(2**-4)] - A2(k)
  1062. ;
  1063. ; Inputs:
  1064. ;   A1T = si.ff ffff | ffff ffff | 0000 0000 (16TC)
  1065. ;   A2P = si.ff ffff | ffff ffff | 0000 0000 (16TC)
  1066. ;
  1067. ; Outputs:
  1068. ;   A1P = Y:(R6) = si.ff ffff | ffff ffff | 0000 0000 (16TC)
  1069. ;
  1070. ;**************************************************************************
  1071.  
  1072.         SUB     X0,B                ;Find A1UL=OME-A2P
  1073.         CMP     B,A     B,X0        ;Check A1T
  1074.         TGT     X0,A                ;If A1T>A1UL, set A1P=A1UL
  1075.         NEG     B       (R2)+       ;Find A1LL=-A1UL=A2P-OME
  1076.         CMP     B,A     B,X0        ;Check A1T again
  1077.         TLT     X0,A                ;If A1T<A1LL, set A1P=A1LL
  1078.         MOVE    A1,Y:(R6)+          ;Store A1P to A1
  1079.         MOVE    (R6)+               ;Adjust coef pointer
  1080.  
  1081. ;**************************************************************************
  1082. ;       FLOATA
  1083. ;
  1084. ; Converts the quantized difference signal from 15-bit
  1085. ;   signed magnitude to floating pt. format (11FL - sign,
  1086. ;   exp, and mant stored separately)
  1087. ;
  1088. ; Inputs:
  1089. ;   DQ = siii iiii | iiii iii.0 | 0000 0000 (15SM)
  1090. ;
  1091. ; Outputs:
  1092. ;   DQ0 = (11FL)
  1093. ;    DQ0EXP = X:(R2) = 0000 0000 | 0000 0000 | 0000 eeee
  1094. ;    DQ0MANT = X:(R2+1) = 01mm mmm0 | 0000 0000 | 0000 0000
  1095. ;    DQ0S = X:(R2+2) = sXXX XXXX | XXXX XXXX | 0000 0000
  1096. ;
  1097. ;**************************************************************************
  1098.  
  1099.         MOVE    X:DQ_T,Y0           ;Get DQS
  1100.         MOVE    Y:DQMAG,A           ;Get MAG=DQMAG
  1101.         TST     A   #$000E,R0       ;Check MAG, get exponent bias (14)
  1102.         JNE     <NORMDQ_T           ;Test MAG
  1103.         MOVE    #<$40,A             ;If MAG=0 set MANT=100000,
  1104.         MOVE    #0,R0               ; and EXP=0
  1105.         JMP     <TRUNCDQ_T
  1106. NORMDQ_T    NORM    R0,A            ;If MAG!=0 do NORM iteration 13
  1107.         NORM    R0,A                ; times to find MSB of MAG
  1108.         NORM    R0,A
  1109.         NORM    R0,A
  1110.         NORM    R0,A
  1111.         NORM    R0,A
  1112.         NORM    R0,A
  1113.         NORM    R0,A
  1114.         NORM    R0,A
  1115.         NORM    R0,A
  1116.         NORM    R0,A
  1117.         NORM    R0,A
  1118.         NORM    R0,A
  1119. ;   A1 = 01?? ???? | ???? ???0 | 0000 0000 = normalized MAG (A2=A0=0)
  1120. ;   R0 = 0000 0000 | 0000 eeee = exponent of normalized MAG
  1121.  
  1122. TRUNCDQ_T   MOVE    #<$7E,X0        ;Get mask
  1123.         AND     X0,A    R0,X:(R2)+  ;Truncate MANT to 6 bits,
  1124.                                     ; save EXP to DQ1EXP
  1125. ;   A1 = 01mm mmm0 | 0000 0000 | 0000 0000  (A2=A0=0)
  1126.         MOVE    A1,X:(R2)+          ;Save MANT to DQ1MANT
  1127.         MOVE    Y0,X:(R2)+          ;Save DQ to DQ1S
  1128.  
  1129. ;**************************************************************************
  1130. ;       FLOATB
  1131. ;
  1132. ; Converts the reconstructed signal from 16-bit two's 
  1133. ;   complement to floating pt. format (11FL - sign,
  1134. ;   exp, and mant stored separately)
  1135. ;
  1136. ; Inputs:
  1137. ;   SR = siii iiii | iiii iiii. | 0000 0000  (16TC)
  1138. ;
  1139. ; Outputs:
  1140. ;   SR0 = (11FL)
  1141. ;    SR0EXP = X:(R2) = 0000 0000 | 0000 0000 | 0000 eeee
  1142. ;    SR0MANT = X:(R2+1) = 01mm mmm0 | 0000 0000 | 0000 0000
  1143. ;    SR0S = X:(R2+2) = sXXX XXXX | XXXX XXXX | 0000 0000
  1144. ;
  1145. ;**************************************************************************
  1146.  
  1147.         MOVE    #15,N2
  1148.         MOVE    Y:SR_T,B            ;Get SR
  1149.         MOVE    (R2)+N2             ;Adjust data pointer
  1150.         ABS     B       B,Y0        ;Find MAG=|SR|, save SRS
  1151.         TST     B   #$000F,R0       ;Load exponent bias
  1152.         JNE     <NORMSR_T           ;Test MAG
  1153.         MOVE    #<$40,B             ;If MAG=0 set MANT=100000,
  1154.         MOVE    #0,R0               ; and EXP=0
  1155.         JMP     <TRUNCSR_T
  1156. NORMSR_T    NORM    R0,B            ;If MAG!=0 do NORM iteration 14
  1157.         NORM    R0,B                ; times to find MSB of MAG
  1158.         NORM    R0,B
  1159.         NORM    R0,B
  1160.         NORM    R0,B
  1161.         NORM    R0,B
  1162.         NORM    R0,B
  1163.         NORM    R0,B
  1164.         NORM    R0,B
  1165.         NORM    R0,B
  1166.         NORM    R0,B
  1167.         NORM    R0,B
  1168.         NORM    R0,B
  1169.         NORM    R0,B
  1170. ;   A1 = 01?? ???? | ???? ???0 | 0000 0000  (A2=A0=0)
  1171. ;   R0 = 0000 0000 | 0000 eeee = exponent of normalized MAG
  1172.  
  1173. TRUNCSR_T   AND     X0,B    R0,X:(R2)+  ;Truncate MANT to 6 bits,
  1174.                                     ; save EXP to SR1EXP
  1175. ;   A1 = 01mm mmm0 | 0000 0000 | 0000 0000  (A2=A0=0)
  1176.         MOVE    B1,X:(R2)+          ;Save MANT to SR1MANT
  1177.         MOVE    Y0,X:(R2)+          ;Save SR to SR1S
  1178.         MOVE    #3,N2
  1179.         MOVE    Y:A2P_T,B           ;Get A2P
  1180.         MOVE    (R2)+N2             ;Adjust data pointer
  1181.  
  1182. ;**************************************************************************
  1183. ;       TONE
  1184. ;
  1185. ; Partial band signal detection
  1186. ;
  1187. ; TD(k) = 1 if A2(k) < -0.71875
  1188. ;         0 otherwise
  1189. ;
  1190. ; Inputs:
  1191. ;   A2P = si.ff ffff | ffff ffff | 0000 0000  (16TC)
  1192. ;
  1193. ; Output:
  1194. ;   TDP = i000 0000 | 0000 0000 | 0000 0000  (1TC)
  1195. ;
  1196. ;**************************************************************************
  1197.  
  1198.         CLR     A   #<$D2,X0        ;Get '-.71875', set TDP=0
  1199.         CMP     X0,B    #<$80,X1    ;Check A2P, get '1'
  1200.         TLT     X1,A                ;If A2P<-.71875 set TDP=1, else TDP=0
  1201.         MOVE    A1,Y:TDP_T          ;Save TDP
  1202.         MOVE    A1,Y:TD_T           ;Save TDP to TD
  1203.  
  1204. ;**************************************************************************
  1205. ;       TRIGB
  1206. ;
  1207. ; Predictor trigger block
  1208. ;
  1209. ; If TR(k) = 1, An(k)=Bn(k)=TD(k)=0
  1210. ;
  1211. ; Inputs:
  1212. ;   TR = i000 0000 | 0000 0000 | 0000 0000  (1TC)
  1213. ;   BnP = si.ff ffff | ffff ffff | 0000 0000  (16TC)
  1214. ;   AnP = si.ff ffff | ffff ffff | 0000 0000  (16TC)
  1215. ;   TDP = i000 0000 | 0000 0000 | 0000 0000  (1TC)
  1216. ;
  1217. ; Output:
  1218. ;   BnR = si.ff ffff | ffff ffff | 0000 0000  (16TC)
  1219. ;   AnR = si.ff ffff | ffff ffff | 0000 0000  (16TC)
  1220. ;   TDR = i000 0000 | 0000 0000 | 0000 0000  (1TC)
  1221. ;
  1222. ;**************************************************************************
  1223.  
  1224.         MOVE    Y:TR_T,B            ;Get TR
  1225.         TST     B       #0,A        ;Test TR
  1226.         JEQ     <FUNCTF_T           ;If TR=0 continue
  1227.         MOVE    A,Y:TD_T            ;If TR=1, set TDR=0,
  1228.         MOVE    A,Y:(R6)+           ; and B1-B6,A1,A2=0
  1229.         MOVE    A,Y:(R6)+
  1230.         MOVE    A,Y:(R6)+
  1231.         MOVE    A,Y:(R6)+
  1232.         MOVE    A,Y:(R6)+
  1233.         MOVE    A,Y:(R6)+
  1234.         MOVE    A,Y:(R6)+
  1235.         MOVE    A,Y:(R6)+
  1236.  
  1237. ;**************************************************************************
  1238. ;       FUNCTF
  1239. ;
  1240. ; Maps quantizer output I into F(I) function
  1241. ;
  1242. ;  |I(k)|  | 7 | 6 | 5 | 4 | 3 | 2 | 1 | 0 |
  1243. ; ---------+---+---+---+---+---+---+---+---+
  1244. ;  F[I(k)] | 7 | 3 | 1 | 1 | 1 | 0 | 0 | 0 |
  1245. ;
  1246. ; Inputs:
  1247. ;   I = siii 0000 | 0000 0000 | 0000 0000
  1248. ;
  1249. ; Output:
  1250. ;   FI = 0iii. 0000 | 0000 0000 | 0000 0000  (3SM)
  1251. ;   IMAG
  1252. ;
  1253. ;**************************************************************************
  1254.  
  1255. FUNCTF_T    MOVE    #<$20,X0
  1256.         MOVE    X:IMAG,A            ;Get |I|
  1257.         CMP     X0,A    #<$50,X0    ;Test for |I|<=2
  1258.         JLE     <RANGE0_T
  1259.         CMP     X0,A    #<$60,X0    ;Test for 3<=|I|<=5
  1260.         JLE     <RANGE1_T
  1261.         CMP     X0,A                ;Test for |I|=6
  1262.         JEQ     <RANGE3_T
  1263.         MOVE    #<$70,A             ;|I|=7, set F[I]=7
  1264.         JMP     <FILTA_T
  1265. RANGE3_T    MOVE    #<$30,A         ;|I|=6, set F[I]=3
  1266.         JMP     <FILTA_T
  1267. RANGE1_T    MOVE    #<$10,A         ;|I|=3,4,or 5, set F[I]=1
  1268.         JMP     <FILTA_T
  1269. RANGE0_T    CLR     A               ;|I|=0,1,or 2, set F[I]=0
  1270.  
  1271. ;**************************************************************************
  1272. ;       FILTA
  1273. ;
  1274. ; Update short term average of F(I)
  1275. ;
  1276. ; DMS(k) = (1 - 2**(-5)) * DMS(k-1) + 2**(-5) * F[I(k)]
  1277. ;
  1278. ; Inputs:
  1279. ;   FI = 0iii. 0000 | 0000 0000 | 0000 0000  (3SM)
  1280. ;   DMS = 0iii. ffff | ffff f000 | 0000 0000  (12SM)
  1281. ;
  1282. ; Output:
  1283. ;   DMSP = 0iii. ffff | ffff f000 | 0000 0000  (12SM)
  1284. ;
  1285. ;**************************************************************************
  1286.  
  1287. FILTA_T MOVE    Y:DMS_T,Y0          ;Get DMS
  1288.         SUB     Y0,A    A,B         ;Find DIF=FI-DMS, save FI
  1289.         MOVE    A,X0    Y:(R7)+,Y1  ;Save DIF, get mask K26
  1290.         MPY     X0,Y1,A Y:(R7)+,X0  ;Find DIFSX=DIF>>5, get mask K27
  1291.         AND     X0,A    Y:DML_T,Y1  ;Truncate DIFSX, get DML
  1292.         ADD     Y0,A    Y:RSHFT+7,X1    ;Find DMSP=DIFSX+DMS
  1293.  
  1294. ;**************************************************************************
  1295. ;       FILTB
  1296. ;
  1297. ; Update long term average of F(I)
  1298. ;
  1299. ; DML(k) = (1 - 2**(-7)) * DML(k-1) + 2**(-7) * F[I(k)]
  1300. ;
  1301. ; Inputs:
  1302. ;   FI = 0iii. 0000 | 0000 0000 | 0000 0000  (3SM)
  1303. ;   DML = 0iii. ffff | ffff fff0 | 0000 0000  (14SM)
  1304. ;
  1305. ; Output:
  1306. ;   DMLP = 0iii. ffff | ffff fff0 | 0000 0000  (14SM)
  1307. ;
  1308. ;**************************************************************************
  1309.  
  1310.         SUB     Y1,B    A1,Y:DMS_T  ;Find DIF=FI-DML
  1311.         MOVE    B1,X0
  1312.         MPY     X0,X1,B Y:(R7)+,X0  ;Find DFISX=DIF>>7, get mask K28
  1313.         AND     X0,B                ;Truncate DIFSX
  1314.         ADD     Y1,B    Y:RSHFT+3,X1    ;Find DMLP=DIFSX+DML
  1315.  
  1316. ;**************************************************************************
  1317. ;       SUBTC
  1318. ;
  1319. ; Compute magnitude of the difference of short and long
  1320. ;  term functions of quantizer output sequence and then
  1321. ;  perform threshold comparison for quantizing speed control
  1322. ;  parameter.
  1323. ;
  1324. ; AX = 1  if Y(k)>=3, TD(k)=1, & |DMS(k)-DML(k)|>(2**-3)*DML(k)
  1325. ;    = 0  otherwise
  1326. ;
  1327. ; Input:
  1328. ;   Y = 0iii i.fff | ffff ff00 | 0000 0000  (13SM)
  1329. ;   DMSP = 0iii. ffff | ffff f000 | 0000 0000  (12SM)
  1330. ;   DMLP = 0iii. ffff | ffff fff0 | 0000 0000  (14SM)
  1331. ;   TDP = i000 0000 | 0000 0000 | 0000 0000  (1TC)
  1332. ;
  1333. ; Output:
  1334. ;   AX = 0i0.0 0000 | 0000 0000 | 0000 0000  (1SM)
  1335. ;
  1336. ;**************************************************************************
  1337.  
  1338.         SUB     B,A     B1,Y:DML_T  ;Find DIF=DMSP-DMLP, save DML
  1339.         ABS     A       B1,Y0       ;Find DIFM=|DIF|
  1340.         MPY     X1,Y0,B     #<$18,Y0    ;Find DTHR=DMLP>>3, get '3'
  1341.         AND     X0,B    #<$40,X0    ;Truncate DTHR, get '1'
  1342.         CMP     B,A     #0,B        ;Compare DIFM & DTHR, set AX=0
  1343.         TGE     X0,B                ;If DIFM>=DTHR set AX=1
  1344.         MOVE    Y:TDP_T,A           ;Get TDP
  1345.         TST     A       X:Y_T,A     ;Check TDP, get Y
  1346.         TNE     X0,B                ;If TDP!=0 set AX=1
  1347.         CMP     Y0,A    X:AP_T,X1   ;Check for Y<"3", get AP
  1348.         TLT     X0,B                ;If Y<"3" set AX=1
  1349.  
  1350. ;**************************************************************************
  1351. ;       FILTC
  1352. ;
  1353. ; Low pass filter of speed control parameter
  1354. ;
  1355. ; AP(k) = (1-2**(-4)) * AP(k-1) + AX
  1356. ;
  1357. ; Inputs:
  1358. ;   AX = 0i0.0 0000 | 0000 0000 | 0000 0000  (1SM)
  1359. ;   AP = 0ii.f ffff | fff0 0000 | 0000 0000  (10SM)
  1360. ;
  1361. ; Outputs:
  1362. ;   APP = 0ii.f ffff | fff0 0000 | 0000 0000  (10SM)
  1363. ;
  1364. ;**************************************************************************
  1365.  
  1366.         SUB     X1,B    Y:RSHFT+4,Y0    ;Find DIF=AX-AP
  1367.         MOVE    B1,X0
  1368.         MPY     X0,Y0,A     Y:(R7)+,X0  ;Find DIFSX=DIF>>4, get K29
  1369.         AND     X0,A    Y:TR_T,B    ;Truncate DIFSX, get TR
  1370.         ADD     X1,A    #<$20,X0    ;Find APP=DIFSX+AP, get '1'
  1371.  
  1372. ;**************************************************************************
  1373. ;       TRIGA
  1374. ;
  1375. ; Speed control trigger block
  1376. ;
  1377. ; AP(k) = AP(k) if TR(k)=0
  1378. ;       =  1    if TR(k)=1
  1379. ;
  1380. ; Inputs:
  1381. ;   TR = i000 0000 | 0000 0000 | 0000 0000  (1TC)
  1382. ;   APP = 0ii.f ffff | fff0 0000 | 0000 0000  (10SM)
  1383. ;
  1384. ; Outputs:
  1385. ;   APR = 0ii.f ffff | fff0 0000 | 0000 0000  (10SM)
  1386. ;
  1387. ;**************************************************************************
  1388.  
  1389.         TST     B   X:IMAG,X1       ;Check TR, get IMAG
  1390.         TMI     X0,A                ;If TR=1 set APR=1, else APR=APP
  1391.         MOVE    A1,X:AP_T           ;Save APR to AP
  1392.  
  1393. ;**************************************************************************
  1394. ;       FUNCTW
  1395. ;
  1396. ; Map quantizer output into logarithmic version of scale
  1397. ;  factor multiplier
  1398. ;
  1399. ;  |I(k)|  |  7  |  6  |  5  |  4  |  3  |  2  |  1  |  0  |
  1400. ; ---------+-----+-----+-----+-----+-----+-----+-----+-----+
  1401. ;   W(I)   |70.13|22.19|12.38| 7.00| 4.00| 2.56| 1.13|-0.75|
  1402. ;
  1403. ; Inputs:
  1404. ;   I = siii. 0000 | 0000 0000 | 0000 0000  (ADPCM format)
  1405. ;
  1406. ; Outputs:
  1407. ;   WI = siii iiii. | ffff 0000 | 0000 0000  (12TC)
  1408. ;
  1409. ;**************************************************************************
  1410.  
  1411.         MOVE    Y:RSHFT+20,X0       ;Get shift constant
  1412.         MPY     X0,X1,A     #WIBASE,R0  ;Shift IM=IMAG for lookup,
  1413.                                     ; load lookup table base
  1414.         MOVE    A1,N0               ;Load IM as offset
  1415.         MOVE    Y:RSHFT+3,X1        ;Get shift constant
  1416.         MOVE    X:Y_T,Y0            ;Get Y
  1417.         MPY     Y0,X1,B     X:(R0+N0),A ;Shift Y>>3,
  1418.                                     ; get WI from lookup table
  1419.  
  1420. ;**************************************************************************
  1421. ;       FILTD
  1422. ;
  1423. ; Update of fast quantizer scale factor
  1424. ;
  1425. ; YU(k) = (1 - 2**(-5)) * Y(k) + 2**(-5) * W[I(k)]
  1426. ;
  1427. ; Inputs:
  1428. ;   WI =  siii iiii. | ffff 0000 | 0000 0000  (12TC)
  1429. ;   Y = 0iii i.fff | ffff ff00 | 0000 0000  (13SM)
  1430. ;
  1431. ; Outputs:
  1432. ;   YUT = 0iii i.fff | ffff ff00 | 0000 0000  (13SM)
  1433. ;
  1434. ;**************************************************************************
  1435.  
  1436.         SUB     B,A                 ;Find DIF=WI-Y
  1437.         ASR     A                   ;Find DIFSX=DIF>>5 (actually DIF>>2)
  1438.         ASR     A   Y:(R7)+,X0      ;Get mask K30
  1439.         AND     X0,A                ;Truncate DIFSX
  1440.         ADD     Y0,A    #<$50,X0    ;Find YUT=DIFSX+Y,
  1441.                                     ; get upper limit '10'
  1442.  
  1443. ;**************************************************************************
  1444. ;       LIMB
  1445. ;
  1446. ; Limit quantizer scale factor
  1447. ;
  1448. ; 1.06 <= YU(k) <= 10.00
  1449. ;
  1450. ; Inputs:
  1451. ;   YUT = 0iii i.fff | ffff ff00 | 0000 0000  (13SM)
  1452. ;
  1453. ; Outputs:
  1454. ;   YUP = 0iii i.fff | ffff ff00 | 0000 0000  (13SM)
  1455. ;
  1456. ;**************************************************************************
  1457.  
  1458.         CMP     X0,A    Y:(R7)+,X1  ;Check for YU>10,
  1459.                                     ; get lower limit '1.06' (K31)
  1460.         TGT     X0,A                ;If YU>10 set YU=10
  1461.         CMP     X1,A    Y:YL_T,Y1   ;Check for YU<1.06, get YL
  1462.         TLT     X1,A                ;If YU<1.06 set YU=1.06
  1463.  
  1464. ;**************************************************************************
  1465. ;       FILTE
  1466. ;
  1467. ; Update of slow quantizer scale factor
  1468. ;
  1469. ; YL(k) = (1 - 2**(-6)) * YL(k-1) + 2**(-6) * YU(k)
  1470. ;
  1471. ; Inputs:
  1472. ;   YUP = 0iii i.fff | ffff ff00 | 0000 0000  (13SM)
  1473. ;   YL = 0iii i.fff | ffff ffff | ffff 0000  (19SM)
  1474. ;
  1475. ; Outputs:
  1476. ;   YLP = 0iii i.fff | ffff ffff | ffff 0000  (19SM)
  1477. ;
  1478. ;**************************************************************************
  1479.  
  1480.         TFR     Y1,B    A1,Y:YU_T   ;Move YL, save YUP
  1481.         NEG     B   Y:(R7)+,Y0      ;Find -YL, save YL, get mask K32
  1482.         AND     Y0,B                ;Truncate -YL (-YL>>6)
  1483.         ADD     B,A     Y:RSHFT+6,Y0    ;Find DIF=YUP+(-YL>>6)
  1484.         MOVE    A1,X1
  1485.         MPY     Y0,X1,A             ;Find DIFSX>>6
  1486.         ADD     Y1,A    R2,X:DATAPTR_T  ;Find YLP=DIFSX+YL,
  1487.                                     ; save transmit data pointer
  1488.         MOVE    A1,Y:YL_T           ;Save YL
  1489.  
  1490. ;**************************************************************************
  1491. ;
  1492. ;   Decoder
  1493. ;
  1494. ;**************************************************************************
  1495.  
  1496. DECODE  MOVE    #PP_R,R1            ;Set partial product ptr to WB1
  1497.         MOVE    X:DATAPTR_R,R2      ;Set data pointer to DQ1EXP
  1498.         MOVE    #COEF_R,R6          ;Set coef pointer to B1
  1499.         MOVE    #CONST1,R7          ;Set pointer to misc constants
  1500.  
  1501. ;**************************************************************************
  1502. ;       FMULT
  1503. ;
  1504. ; Multiply predictor coefficients with corresponding
  1505. ;   quantized difference signal or reconstructed signal
  1506. ;
  1507. ;   Data (DQn or SRn) is stored in 11FL format (separate),
  1508. ;   & coefficient (Bn or An) is stored in 16TC format.
  1509. ;
  1510. ; Computes  [An(k-1) * SR(k-n)] or [Bn(k-1) * DQ(k-n)]
  1511. ;
  1512. ; Flow Description:
  1513. ;   1. Convert 16TC An to 13SM AnMAG
  1514. ;   2. Convert 13SM AnMAG to 10FL (AnEXP and AnMANT)
  1515. ;   3. Add SRnEXP to AnEXP to get WAnEXP (5-bits)
  1516. ;   4. Multiply SRnMANT with AnMANT, add '48', and truncate
  1517. ;       to 8-bits to get WAnMANT
  1518. ;   5. Convert 13FL (WAnEXP & WAnMANT) to 15SM WAnMAG
  1519. ;   6. XOR AnS with SRnS to find WAnS
  1520. ;   7. Convert 16SM (WAnMAG & WAnS) to 16TC WAn
  1521. ;
  1522. ; Input:
  1523. ;   SRn = (11FL)
  1524. ;    SRnEXP = X:(R2) = 0000 0000 | 0000 0000 | 0000 eeee
  1525. ;    SRnMANT = X:(R2+1) = 01mm mmm0 | 0000 0000 | 0000 0000
  1526. ;    SRnS = X:(R2+2) = sXXX XXXX | XXXX XXXX | 0000 0000
  1527. ;       (DQ in same format as SR)
  1528. ;
  1529. ;   An = Y:(R6) = si.ff ffff | ffff ffff | 0000 0000 (16TC)
  1530. ;       (Bn in same format as An)
  1531. ;
  1532. ; Output:
  1533. ;   WAn = X:(R1) = siii iiii | iiii iii.f | 0000 0000  (16TC)
  1534. ;       (WBn in same format as WAn)
  1535. ;
  1536. ;**************************************************************************
  1537.  
  1538.         MOVE    #CONST,R0           ;Set pointer to FMULT constants
  1539.         MOVE    #0,Y1
  1540.         DO      #8,ACCUM_R          ;Execute mult 8 times
  1541.  
  1542. ; 1. Convert 16TC An to 13SM AnMAG
  1543.         MOVE    X:(R0)+,X1  Y:(R6),A    ;Get An and mask KF1
  1544.         AND     X1,A    X:(R0)+,X1  ;Truncate An to 13 bits (An>>2),
  1545.                                     ; get mask KF2
  1546.         ABS     A       #$000D,R4   ;Find AnMAG, load
  1547.                                     ; exponent bias (13) into R4
  1548.         AND     X1,A    #<$7E,X1    ;Truncate any ovrflw, get mask
  1549. ;   A1 = 0i.ff ffff | ffff ff00 | 0000 0000 (A2=A0=0)
  1550.  
  1551. ; 2. Convert 13SM AnMAG to 10FL (AnEXP and AnMANT)
  1552.         JNE     <NORMAN_R           ;Test AnMAG
  1553.         MOVE    #<$40,A             ;If AnMAG=0, set AnMANT=1<<5,
  1554.         MOVE    #0,R4               ; and AnEXP=0
  1555.         JMP     <CONTIN_R
  1556. NORMAN_R    NORM    R4,A            ;If AnMAG!=0 do NORM iteration
  1557.         NORM    R4,A                ; 12 times to find MSB
  1558.         NORM    R4,A
  1559.         NORM    R4,A
  1560.         NORM    R4,A
  1561.         NORM    R4,A
  1562.         NORM    R4,A
  1563.         NORM    R4,A
  1564.         NORM    R4,A
  1565.         NORM    R4,A
  1566.         NORM    R4,A
  1567.         NORM    R4,A
  1568. ;   A1 = 01?? ???? | ???? ??00 | 0000 0000 = AnMANT
  1569. ;   R4 = 0000 0000 | 0000 eeee = AnEXP
  1570. CONTIN_R    AND     X1,A    R4,B    ;Truncate AnMANT to 6 bits,
  1571.                                     ; move AnEXP to B
  1572. ;   A1 = 01mm mmm0 | 0000 0000 | 0000 0000 (A2=A0=0)
  1573. ;   B1 = 0000 0000 | 0000 0000 | 0000 eeee (B2=B0=0)
  1574.  
  1575. ; 3. Add SRnEXP to AnEXP to get WAnEXP (5-bits)
  1576.         MOVE    X:(R2)+,X1  A,Y0    ;Get SRnEXP
  1577.         ADD     X1,B    X:(R2)+,X1  ;Find WAnEXP=SRnEXP+AnEXP,
  1578.                                     ; get SRnMANT 
  1579. ;   B1 = 0000 0000 | 0000 0000 | 000e eeee (B2=B0=0)
  1580.  
  1581. ; 4. Multiply SRnMANT with AnMANT, add '48', and truncate
  1582. ;       to 8-bits to get WAnMANT
  1583. ;   Y0 = 01mm mmm0 | 0000 0000 | 0000 0000
  1584. ;   X1 = 01mm mmm0 | 0000 0000 | 0000 0000
  1585.         MPY     Y0,X1,A     X:(R0)+,X0  ;Find WAnMANT, get '48' (KF3)
  1586. ;   A1 = 0mmm mmmm | mmmm m000 | 0000 0000 (A2=A0=0)
  1587. ;   X0 = 0000 0001 | 1000 0000 | 0000 0000 = '48'
  1588.         ADD     X0,A        X:(R0)+,X0  ;Add '48' to WAnMANT, get mask KF4
  1589.         AND     X0,A        X:(R0)+,X0  ;Truncate WAnMANT to 8 bits,
  1590.                                         ; get '26' (KF5)
  1591. ;   A1 = 0mmm mmmm | m000 0000 | 0000 0000 (A2=A0=0)
  1592.  
  1593. ; 5. Convert 13FL (WAnEXP & WAnMANT) to 15SM WAnMAG
  1594. ;   X0 = 0000 0000 | 0000 0000 | 0001 1010 = '26'
  1595. ;   B1 = 0000 0000 | 0000 0000 | 000e eeee (B2=B0=0) 
  1596.         SUB     X0,B    X:(R0)+,X0  ;Find shift offset (WAnEXP-26),
  1597.                                     ; get mask KF6
  1598.         JEQ     <TRUNC_R            ;If offset=26 no shift
  1599.         JMI     <RIGHT_R            ;If offset<26 do right shift
  1600.                                     ;Else offset>26, do left shift
  1601.         REP     B1                  ;Offset>26, shift WAnMANT
  1602.         LSL     A                   ; left up to 4 times
  1603.         JMP     <TRUNC_R
  1604. RIGHT_R ABS     B       #>$0F,Y0    ;Find |offset|, get '15'
  1605.         CMP     Y0,B    B1,N5       ;Compare |offset| to '15',
  1606.                                     ; load offset for shift
  1607.         TGE     Y1,A                ;If |offset|>=15 WAnMAG=0
  1608.         MOVE    A1,X1               ;Move WAnMANT for shift
  1609.         MOVE    Y:(R5+N5),Y0        ;Lookup shift constant
  1610.         MPY     Y0,X1,A             ;Shift WAnMANT right up to 14 times
  1611. ;   A1 = ?mmm mmmm | mmmm mmmm | ???? ???? (A2=A0=0)
  1612. TRUNC_R AND     X0,A    X:(R2)+,X1  Y:(R6)+,B   ;Truncate WAnMAG to 15 bits,
  1613.                                     ; get SRnS & AnS
  1614. ;   A1 = 0iii iiii | iiii iii.f | 0000 0000 (A2=A0=0)
  1615.         NEG     A   A1,X0           ;Find -WAnMAG, save WAnMAG
  1616.  
  1617. ; 6. XOR AnS with SRnS to find WAnS
  1618. ;   B1 = sXXX XXXX | XXXX XXXX | 0000 0000 (B2=sign ext, B0=0)
  1619. ;   X1 = sXXX XXXX | XXXX XXXX | 0000 0000
  1620.         EOR     X1,B    #CONST,R0   ;Find WAnS (in MSB of B),
  1621.                                     ; update pointer to constants
  1622.  
  1623. ; 7. Convert 16SM (WAnMAG & WAnS) to 16TC WAn
  1624.         TPL     X0,A                ;If WAnS=0 use WAnMAG, else use -WAnMAG
  1625. ;   A1 = siii iiii | iiii iii.f | 0000 0000  (A2=sign ext, A0=0)
  1626.         MOVE    A1,X:(R1)+          ;Save WAn
  1627.  
  1628. ;**************************************************************************
  1629. ;       ACCUM
  1630. ;
  1631. ; Add predictor outputs to form the partial signal estimate
  1632. ;   and the signal estimate
  1633. ;
  1634. ; SEZ(k) = [B1(k-1) * DQ(k-1)] + ... + [B6(k-1) * DQ(k-6)]
  1635. ;        = WB1 + WB2 + ... + WB6
  1636. ;
  1637. ; SE(k) = SEZ(k) + [A1(k-1) * SR(k-1)] + [A2(k-1) * SR(k-2)]
  1638. ;       = SEZ + WA1 + WA2
  1639. ;
  1640. ; Inputs:
  1641. ;   WBn & WAn = X:(R1) = siii iiii | iiii iii.f | 0000 0000  (16TC)
  1642. ;
  1643. ; Outputs:
  1644. ;   SEZ = siii iiii | iiii iii.0 | 0000 0000  (15TC)
  1645. ;   SE = siii iiii | iiii iii.0 | 0000 0000  (15TC)
  1646. ;
  1647. ;**************************************************************************
  1648.  
  1649. ACCUM_R MOVE    X:(R1)+,A           ;Get WB1
  1650.         MOVE    X:(R1)+,X0          ;Get WB2
  1651.         ADD     X0,A    X:(R1)+,X0  ;Accumulate WB1&WB2, get WB3
  1652.         ADD     X0,A    X:(R1)+,X0  ;Accumulate WB3, get WB4
  1653.         ADD     X0,A    X:(R1)+,X0  ;Accumulate WB4, get WB5
  1654.         ADD     X0,A    X:(R1)+,X0  ;Accumulate WB5, get WB6
  1655.         ADD     X0,A    X:(R1)+,X0  ;Accumulate WB6 to get SEZI, get WA1
  1656.         TFR     A,B     Y:(R7)+,X1  ;Copy SEZI, get mask K1
  1657.         AND     X1,B    X:AP_R,Y0   ;Truncate SEZI, get AP
  1658.         ADD     X0,A    X:(R1)+,X0  ;Accumulate WA1, get WA2
  1659.         ADD     X0,A    B1,Y:SEZ_R  ;Accumulate WA2 to get SEI, save SEZ
  1660.         AND     X1,A    #<$20,X0    ;Truncate SEI, get '1'
  1661.         TFR     Y0,A    A1,Y:SE_R   ;Move AP, save SE
  1662.  
  1663. ;**************************************************************************
  1664. ;       LIMA
  1665. ;
  1666. ; Limit speed control parameter
  1667. ;
  1668. ; AL(k) = 1        if AP(k-1) > 1
  1669. ;       = AP(k-1)  if AP(k-1) <= 1
  1670. ;
  1671. ; Inputs:
  1672. ;   AP = 0ii.f ffff | fff0 0000 | 0000 0000  (10SM)
  1673. ;
  1674. ; Outputs:
  1675. ;   AL = 0i.ff ffff | 0000 0000 | 0000 0000  (7SM)
  1676. ;
  1677. ;**************************************************************************
  1678.  
  1679.         CMP     X0,A    Y:YL_R,B    ;Test AP, get YL
  1680.         TGT     X0,A                ;If AP>'1' set AL='1'
  1681.         LSL     A       #<$7F,X0    ;Shift to align radix pt., get mask
  1682.         AND     X0,A    Y:(R7)+,X0  ;Truncate AL (AP>>2), get mask K2
  1683.  
  1684. ;**************************************************************************
  1685. ;       MIX
  1686. ;
  1687. ; Form linear combination of fast and slow quantizer
  1688. ;   scale factors
  1689. ;
  1690. ; Y(k) = AL(k) * YU(k-1) + [1 - AL(k)] * YL(k-1)
  1691. ;
  1692. ; Inputs:
  1693. ;   YL = 0iii i.fff | ffff ffff | ffff 0000  (19SM)
  1694. ;   AL = 0i.ff ffff | 0000 0000 | 0000 0000  (7SM)
  1695. ;   YU = 0iii i.fff | ffff ff00 | 0000 0000  (13SM)
  1696. ;
  1697. ; Outputs:
  1698. ;   Y = 0iii i.fff | ffff ff00 | 0000 0000  (13SM)
  1699. ;
  1700. ;**************************************************************************
  1701.  
  1702.         AND     X0,B    A,X0    Y:YU_R,A    ;Truncate YL (YL>>6), get YU
  1703.         SUB     B,A     B,Y1    X0,X:AL_R   ;Find DIF=YU-YL, save YL, get AL
  1704.         ABS     A       A,B         ;Find DIFM=|DIF|, save DIFS
  1705.         MOVE    A1,Y0
  1706.         MPY     X0,Y0,A     Y:(R7)+,X0  ;Find DIFM*AL, get mask K3
  1707.         AND     X0,A                ;Truncate to find PRODM=(DIFM*AL)>>6
  1708.         NEG     A   A1,X0           ;Find -PRODM, save PRODM
  1709.         TST     B                   ;Check DIFS
  1710.         TPL     X0,A                ;If DIFS=0 PROD=PRODM,
  1711.                                     ; else PROD=-PRODM
  1712.         ASL     A   Y1,B            ;Line up radix point
  1713.         ADD     Y1,A                ;Find Y=PROD+(YL>>6)
  1714.         MOVE    A,X:Y_R             ;Save Y
  1715.  
  1716. ;**************************************************************************
  1717. ;
  1718. ; Input ADPCM data (I) here. For simulation purposes the Input 
  1719. ; Word from File subroutine on the 56001 ADS board is used.
  1720. ;
  1721. ;**************************************************************************
  1722.  
  1723.         MOVE    #2,X0               ;Input ADPCM word (I)
  1724.         JSR     $E002
  1725.  
  1726. ;**************************************************************************
  1727. ;       RECONST
  1728. ;
  1729. ; Reconstruct quantized difference signal in the log domain
  1730. ;
  1731. ;     |I(k)| | log2|DQ(k)| - Y(k)
  1732. ;    --------+-------------------
  1733. ;       7    |      3.32
  1734. ;       6    |      2.91
  1735. ;       5    |      2.52
  1736. ;       4    |      2.13
  1737. ;       3    |      1.66
  1738. ;       2    |      1.05
  1739. ;       1    |      0.031
  1740. ;       0    |      - inf
  1741. ;
  1742. ; Inputs:
  1743. ;   I = iiii 0000 | 0000 0000 | 0000 0000  (ADPCM format)
  1744. ;
  1745. ; Output:
  1746. ;   DQLN = siii i.fff | ffff 0000 | 0000 0000  (12TC)
  1747. ;   DQS = sXXX 0000 | 0000 0000 | 0000 0000  (1TC)
  1748. ;
  1749. ;**************************************************************************
  1750.  
  1751.         MOVE    #<$F0,X1
  1752.         MOVE    A,Y1    A,X:I_R     ;Save DQS (sign of I) to Y1
  1753.         EOR     X1,A    Y:RSHFT+20,Y0   ;Invert bits of I
  1754.         TMI     Y1,A                ;If ^IS=1, use I, else use ^I
  1755. ;   A1 = 0iii 0000 | 0000 0000 | 0000 0000 (A2=?, A0=0)
  1756.         MOVE    A1,X0
  1757.         MOVE    A1,X:IMAG           ;Save |I|
  1758.         MPY     X0,Y0,A     #IQUANTAB,R4    ;Shift IMAG>>20
  1759. ;   A1 = 0000 0000 | 0000 0000 | 0000 0iii (A2=A0=0)
  1760.         MOVE    A1,N4               ;Load IMAG as offset
  1761.         MOVE    X:Y_R,B             ; into IQUAN table, get Y
  1762.         MOVE    #CONST8,R7          ;Adjust constant pointer
  1763.         MOVE    X:(R4+N4),A         ;Lookup DQLN
  1764.  
  1765. ;**************************************************************************
  1766. ;       ADDA
  1767. ;
  1768. ; Add scale factor to log version of quantized difference
  1769. ;   signal
  1770. ;
  1771. ; DQL = DQLN + Y
  1772. ;
  1773. ; Inputs:
  1774. ;   Y = 0iii i.fff | ffff ff00 | 0000 0000  (13SM)
  1775. ;   DQLN = siii i.fff | ffff 0000 | 0000 0000  (12TC)
  1776. ;
  1777. ; Output:
  1778. ;   DQL = siii i.fff | ffff 0000 | 0000 0000  (12TC)
  1779. ;
  1780. ;**************************************************************************
  1781.  
  1782.         MOVE    Y:(R7)+,Y0          ;Get mask K8 for ADDA
  1783.         AND     Y0,B    Y:(R7)+,X0  ;Truncate Y to 11 bits (Y<<2),
  1784.                                     ; get mask K9
  1785.         ADD     B,A     #<$08,X1    ;Find DQL=DQLN+(Y<<2), get '1'
  1786.    
  1787. ;**************************************************************************
  1788. ;       ANTILOG
  1789. ;
  1790. ; Convert quantized difference signal from log to linear
  1791. ;   domain
  1792. ;
  1793. ; Input:
  1794. ;   DQL = siii i.fff | ffff 0000 | 0000 0000  (12TC)
  1795. ;   DQS = sXXX 0000 | 0000 0000 | 0000 0000  (1TC)
  1796. ;
  1797. ; Outputs:
  1798. ;   DQ = siii iiii | iiii iii.0 | 0000 0000  (15SM)
  1799. ;
  1800. ;**************************************************************************
  1801.  
  1802.         JPL     <CONVLOG_R          ;If DQL>=0 (DS=0) convert DQL,
  1803.                                     ; else DQL<0 (DS=1), set |DQ|=0
  1804.         TFR     Y1,A    #<$80,X0    ;Get DQS (MSB of I), get mask
  1805.         AND     X0,A    #0,B        ;Mask off DQS, set |DQ|=0
  1806. ;   A1 = s000 0000 | 0000 0000 | 0000 0000  (A2=sign ext, A0=0)
  1807.         MOVE    B1,Y:DQMAG          ;Save DQMAG=|DQ|
  1808.         MOVE    (R7)+               ;Adjust constant pointer
  1809.         MOVE    (R7)+
  1810.         JMP     <SAVEDQ_R
  1811.  
  1812. CONVLOG_R   AND     X0,A    A,B     ;Find fractional part (DMN),
  1813.                                     ; save DS
  1814. ;   A1 = 0000 0.fff | ffff 0000 | 0000 0000  (A2=A0=0)
  1815.         OR      X1,A    #<$78,X0    ;Add implied '1' to DMN to
  1816.                                     ; find DQT, get integer mask
  1817. ;   A1 = 0000 1.fff | ffff 0000 | 0000 0000  (A2=A0=0)
  1818.         AND     X0,B    Y:RSHFT+19,Y0   ;Find integer part (DEX),
  1819.                                     ; get shift constant
  1820. ;   B1 = 0iii i.000 | 0000 0000 | 0000 0000  (B2=B0=0)
  1821.         MOVE    B1,X0
  1822.         MPY     X0,Y0,B     Y:(R7)+,X0  ;Shift DEX>>19, get '10' (K10)
  1823. ;   A1 = 0000 1.fff | ffff 0000 | 0000 0000  (A2=A0=0)
  1824. ;   B1 = 0000 0000 | 0000 0000 | 0000 iiii.  (B2=B0=0)
  1825.         SUB     X0,B    Y:(R7)+,X0  ;Find DQT shift=DEX-'10',
  1826.                                     ; get mask K11
  1827.         JEQ     <TRUNCDQM_R         ;If DEX=10, no shift
  1828.         JLT     <SHFRDQ_R           ;If DEX<10, shift right
  1829.         REP     B1                  ;Else shift DQT left
  1830.         LSL     A                   ; up to 4 times
  1831.         JMP     <TRUNCDQM_R
  1832.  
  1833. SHFRDQ_R    NEG     B               ;Find 10-DEX
  1834.         MOVE    B1,N5               ;Use 10-DEX for shift lookup
  1835.         MOVE    A1,Y0
  1836.         MOVE    Y:(R5+N5),X1        ;Lookup shift constant
  1837.         MPY     X1,Y0,A             ;Shift DQT right up to 9 times
  1838. TRUNCDQM_R  AND     X0,A    #<$80,B ;Truncate to find DQMAG=|DQ|,
  1839.                                     ; get sign mask
  1840. ;   A1 = 0iii iiii | iiii iii.0 | 0000 0000  (A2=A0=0)
  1841.         AND     Y1,B    A1,Y:DQMAG  ;Mask off DQS, save DQMAG           
  1842. ;   B1 = s000 0000 | 0000 0000 | 0000 0000  (B2=?, B0=0)
  1843.         MOVE    B1,X0
  1844.         OR      X0,A                ;Add DQS to DQMAG to get DQ
  1845. ;   A1 = siii iiii | iiii iii.0 | 0000 0000  (A2=?, A0=0)
  1846. SAVEDQ_R    MOVE    A1,X:DQ_R       ;Save DQ
  1847.  
  1848. ;**************************************************************************
  1849. ;       TRANS
  1850. ;
  1851. ; Transition detector
  1852. ;
  1853. ; TR(k) = 1 if TD(k)=1 and |DQ(k)|> 24 x 2**(YL(k))
  1854. ;         0 otherwise
  1855. ;
  1856. ; Inputs:
  1857. ;   TD = i000 0000 | 0000 0000 | 0000 0000  (1TC)
  1858. ;   YL = 0iii i.fff | ffff ffff | ffff 0000  (19SM)
  1859. ;   DQ = siii iiii | iiii iii.0 | 0000 0000  (15SM)
  1860. ;
  1861. ; Output:
  1862. ;   TR = i000 0000 | 0000 0000 | 0000 0000  (1TC)
  1863. ;
  1864. ;**************************************************************************
  1865.  
  1866.         MOVE    Y:TD_R,A            ;Get TD
  1867.         TST     A   #0,A            ;Check TD, set TR=0
  1868.         JEQ     <SAVETR_R           ;If TD=0 save TR=0
  1869.                                     ; else test DQ and YL
  1870.         MOVE    Y:YL_R,A            ;Get YL
  1871.         TFR     A,B     Y:(R7)+,X0  ;Save YL, get mask K12
  1872.         AND     X0,A    #<$08,X0    ;Find YLFRAC (YL>>10), get '1'
  1873.         OR      X0,A    B,X1    Y:(R7)+,Y1  ;Add implied '1' to YLFRAC,
  1874.                                     ; get mask K13
  1875.         MPY     Y1,X1,B     Y:(R7)+,X0  ;Find YLINT=YL>>15, get '8' (K14)
  1876.         MOVE    B1,B                ;Adjust sign extension
  1877.         CMP     X0,B    Y:(R7)+,X0  ;Compare YLINT to '8', get '5' (K15)
  1878.         JGT     <MAXTHR_R           ;If YLINT>8 set maximum THR2
  1879.         SUB     X0,B                ;Find YLINT-5
  1880.         JEQ     <SETDQTHR_R         ;If YLINT=5 don't shift
  1881.         JLT     <RSHFT_R            ;If YLINT<5 shift right
  1882.  
  1883.         REP     B1                  ;Else shift YLFRAC left
  1884.         LSL     A                   ; up to 3 times to get THR1
  1885.         JMP     <SETDQTHR_R
  1886.  
  1887. MAXTHR_R    MOVE    #<$7C,A         ;Set maximum THR2 (31<<9)
  1888.         JMP     <SETDQTHR_R
  1889.  
  1890. RSHFT_R NEG     B                   ;Find 5-YLINT
  1891.         MOVE    B1,N5               ;Use 5-YLINT for shift lookup
  1892.         MOVE    A1,X0
  1893.         MOVE    Y:(R5+N5),X1        ;Lookup shift constant
  1894.         MPY     X0,X1,A             ;Shift YLFRAC right up to ? times
  1895.                                     ; to get THR1
  1896. SETDQTHR_R  TFR     A,B     Y:(R7)+,X0  ;Get mask K16
  1897.         LSR     B                   ;Find THR2>>1
  1898.         AND     X0,B                ;Truncate THR2>>1
  1899.         ADD     B,A     #0,X1       ;Find THR2+(THR2>>1)
  1900.         LSR     A                   ;Find (THR2+(THR2>>1)>>1
  1901.         AND     X0,A    Y:DQMAG,X0  ;Truncate to find DQTHR, get DQMAG
  1902.         CMP     X0,A    #<$80,A     ;Compare DQMAG to DQTHR, set TR=1
  1903.         TGT     X1,A                ;If DQMAG>DQTHR leave TR=1,
  1904.                                     ; else DQMAG<=DQTHR, set TR=0
  1905. SAVETR_R    MOVE    A1,Y:TR_R       ;Save TR
  1906.  
  1907. ;**************************************************************************
  1908. ;       ADDB
  1909. ;
  1910. ; Add quantized difference signal and signal estimate
  1911. ;   to form reconstructed signal
  1912. ;
  1913. ; SR(k-n) = SE(k-n) + DQ(k-n)
  1914. ;
  1915. ; Inputs:
  1916. ;   DQ = siii iiii | iiii iii.0 | 0000 0000  (15SM)
  1917. ;   SE = siii iiii | iiii iii.0 | 0000 0000  (15TC)
  1918. ;
  1919. ; Output:
  1920. ;   SR = siii iiii | iiii iiii. | 0000 0000  (16TC)
  1921. ;
  1922. ;**************************************************************************
  1923.  
  1924.         MOVE    Y:SE_R,B            ;Get SE
  1925.         ASR     B   X:DQ_R,A        ;Sign extend SE to get SEI, get DQS
  1926.         TST     A       Y:DQMAG,A   ;Check DQS, get DQMAG
  1927.         JPL     <SHFTDQ_R           ;If DQS=0 continue
  1928.         NEG     A                   ;Convert DQ to 2's comp
  1929. SHFTDQ_R    ASR     A               ;Sign extend DQ to get DQI
  1930.         ADD     A,B     #CONST17,R7 ;Find SR=DQ+SE, update const pointer
  1931.  
  1932. ;**************************************************************************
  1933. ;       ADDC
  1934. ;
  1935. ; Obtain sign of addition of the quantized difference
  1936. ;   signal and the partial signal estimate
  1937. ;
  1938. ; P(k) = DQ(k) + SEZ(k)
  1939. ; PK0 = sign of P(k)
  1940. ;
  1941. ; Inputs:
  1942. ;   DQ = siii iiii | iiii iii.0 | 0000 0000  (15SM)
  1943. ;   SEZ = siii iiii | iiii iii.0 | 0000 0000 (15TC)
  1944. ;
  1945. ; Output:
  1946. ;   PK0 = sXXX XXXX | XXXX XXXX | 0000 0000  (1TC)
  1947. ;   SIGPK = i000 0000 | 0000 0000 | 0000 0000  (1TC)
  1948. ;
  1949. ;**************************************************************************
  1950.  
  1951.         MOVE    B1,Y:SR_R           ;Save SR
  1952.         MOVE    Y:SEZ_R,B           ;Get SEZ
  1953.         ASR     B                   ;Sign extend SEZ to SEZI
  1954.         ADD     B,A     #0,B        ;Find DQSEZ=DQ+SEZ,
  1955.                                     ; set SIGPK=0
  1956.         TST     A   #<$80,X0        ;Check DQSEZ, get '1'
  1957.         TEQ     X0,B                ;If DQSEZ=0, SIGPK=1,
  1958.                                     ; else SIGPK=0
  1959.  
  1960.         MOVE    Y:PK1_R,X0
  1961.         MOVE    X0,Y:PK2_R          ;Delay previous PK1
  1962.         MOVE    Y:PK0_R,X0
  1963.         MOVE    X0,Y:PK1_R          ;Delay previous PK0
  1964.         MOVE    A1,Y:PK0_R          ;Save new PK0
  1965.         MOVE    B1,Y:SIGPK_R        ;Save SIGPK
  1966.         EOR     X0,A    Y:PK2_R,X0  ;Find PKS1=PK0**PK1
  1967.                                     ; for UPA1 & UPA2
  1968.         MOVE    A1,X:PKS1           ;Save PKS1
  1969.         MOVE    Y:PK0_R,A
  1970.         EOR     X0,A    #3,N2       ;Find PKS2=PK0**PK2 for UPA2
  1971.         MOVE    A1,X:PKS2           ;Save PKS2
  1972.         MOVE    (R2)+               ;Adjust data buffer pointer so
  1973.         MOVE    (R2)+               ; that R2 points to DQ1S
  1974.  
  1975. ;**************************************************************************
  1976. ;       XOR
  1977. ;
  1978. ; Find one bit "exclusive or" of the sign of difference
  1979. ;   signal and the sign of delayed difference signal.
  1980. ;
  1981. ; Un = sgn[DQ(k)] XOR sgn[DQ(k-n)]
  1982. ;
  1983. ; Inputs:
  1984. ;   DQ = siii iiii | iiii iii.0 | 0000 0000 (15SM)
  1985. ;   DQnS = X:(R2+n) sXXX XXXX | XXXX XXXX | 0000 0000
  1986. ;
  1987. ; Outputs:
  1988. ;   Un = sXXX XXXX | XXXX XXXX | 0000 0000 (1TC)
  1989. ;
  1990. ;**************************************************************************
  1991. ;**************************************************************************
  1992. ;       UPB
  1993. ;
  1994. ; Update the coefficients of the sixth order predictor
  1995. ;
  1996. ; Bn(k) = [1-(2**-8)] * Bn(k-1)
  1997. ;           + (2**-7) * sgn[DQ(k)] * sgn[DQ(k-n)]
  1998. ;
  1999. ; Inputs:
  2000. ;   Bn = Y:(R6+n) = si.ff ffff | ffff ffff | 0000 0000 (16TC)
  2001. ;   DQ = siii iiii | iiii iii.0 | 0000 0000 (15SM)
  2002. ;   Un = sXXX XXXX | XXXX XXXX | 0000 0000 (1TC)
  2003. ;
  2004. ; Outputs:
  2005. ;   BnP = Y:(R6+n) = si.ff ffff | ffff ffff | 0000 0000 (16TC)
  2006. ;
  2007. ;**************************************************************************
  2008.  
  2009.         MOVE    Y:DQMAG,A           ;Get DQMAG
  2010.         TST     A   X:DQ_R,Y0       ;Check DQMAG, get DQS
  2011.         JNE     <XORUPB_R           ;If DQMAG!=0 use section with XOR,
  2012.                                     ; else use section with no XOR
  2013.                                     ; (because UGBn=0 if DQMAG=0)
  2014.  
  2015. ; UPB without XOR
  2016.         MOVE    Y:RSHFT+8,X1        ;Get shift constant
  2017.         MOVE    (R7)+               ;Adjust constant pointer
  2018.         MOVE    (R7)+
  2019.         MOVE    Y:(R7)+,X0          ;Get mask K19
  2020.         DO      #6,ENDLOOP_R        ;Do UPB for B1-B6
  2021.         MOVE    X:(R2)+N2,A     Y:(R6),Y1   ;Get Bn (& DQnS but don't use)
  2022.         MPY     X1,Y1,A             ;Find Bn>>8
  2023.         AND     X0,A                ;Truncate (Bn>>8)
  2024.         NEG     A                   ;Find UBn=ULBn=-(Bn>>8)
  2025.         ADD     Y1,A                ;Find BnP=Bn+UBn
  2026.         MOVE    A1,Y:(R6)+          ;Store BnP to Bn
  2027. ENDLOOP_R   JMP     <UPA2_R
  2028.  
  2029. ; UPB with XOR
  2030. XORUPB_R    MOVE    Y:(R7)+,X0      ;Get +gain (K17)
  2031.         DO      #6,UPTR_R           ;Do UPB and XOR for B1-B6
  2032.         MOVE    X:(R2)+N2,A     Y:(R6),Y1   ;Get Bn & DQnS
  2033.         EOR     Y0,A    Y:(R7)+,X1  ;Find Un=DQS**DQnS (XOR),
  2034.                                     ; get -gain (K18)
  2035.         TPL     X0,A                ;If Un=0 set UGBn=+gain
  2036.         TMI     X1,A                ;If Un=1 set UGBn=-gain
  2037.         MOVE    Y:RSHFT+8,X1        ;Get shift constant
  2038.         MPY     X1,Y1,B     Y:(R7)-,X1  ;Shift Bn>>8, get mask K19
  2039.         AND     X1,B                ;Truncate (Bn>>8)
  2040.         NEG     B                   ;Find ULBn=-(Bn>>8)
  2041.         ADD     B,A                 ;Find UBn=UGBn+ULBn
  2042.         ADD     Y1,A                ;Find BnP=Bn+UBn
  2043.         MOVE    A1,Y:(R6)+          ;Store BnP to Bn
  2044. UPTR_R  MOVE    (R7)+               ;Adjust constant pointer
  2045.         MOVE    (R7)+
  2046.  
  2047. ;**************************************************************************
  2048. ;       UPA2
  2049. ;
  2050. ; Update the A2 coefficient of the second order predictor.
  2051. ;
  2052. ; A2(k) = [1-(2**-7)] * A2(k-1)
  2053. ;           + (2**-7) * { sgn[P(k)] * sgn[P(k-2)]
  2054. ;               - F[A1(k-1)] * sgn[P(k)] * sgn[P(k-1)] }
  2055. ;
  2056. ; F[A1(k)] = 4 * A1       if |A1|<=(2**-1)
  2057. ;          = 2 * sgn(A1)  if |A1|>(2**-1)
  2058. ;
  2059. ; Inputs:
  2060. ;   A1 = Y:(R6) = si.ff ffff | ffff ffff | 0000 0000 (16TC)
  2061. ;   A2 = Y:(R6+1) = si.ff ffff | ffff ffff | 0000 0000 (16TC)
  2062. ;   SIGPK = i000 0000 | 0000 0000 | 0000 0000  (1TC)
  2063. ;   PK0 = sXXX XXXX | XXXX XXXX | 0000 0000  (1TC)
  2064. ;   PK1 = sXXX XXXX | XXXX XXXX | 0000 0000  (1TC)
  2065. ;   PK2 = sXXX XXXX | XXXX XXXX | 0000 0000  (1TC)
  2066. ;     (Note: PKS1 & PKS2 have been previously calculated)
  2067. ;
  2068. ; Outputs:
  2069. ;   A2T = si.ff ffff | ffff ffff | 0000 0000 (16TC)
  2070. ;
  2071. ;**************************************************************************
  2072.  
  2073. UPA2_R  MOVE    X:PKS2,A            ;Get PKS2=PK0**PK2
  2074.         TST     A   #<$10,Y0        ;Check PKS2, get '+1'
  2075.         MOVE    #<$F0,Y1            ;Get '-1'
  2076.         TPL     Y0,A                ;If PKS2=0, set UGA2A='+1'
  2077.         TMI     Y1,A                ;If PKS2=1, set UGA2A='-1'
  2078.         MOVE    A,X1    Y:(R6)+,A   ;Save UGA2A, get A1
  2079.         MOVE    Y:(R7)+,Y0          ;Get '+1.99' (K20)
  2080.         CMP     Y0,A    Y:(R7)+,Y1  ;Check A1, get '-1.99' (K21)
  2081.         TGT     Y0,A                ;If A1>=1/2, set FA1='1.99'
  2082.         CMP     Y1,A    X:PKS1,B    ;Check A1 again, get PKS1=PK0**PK1
  2083.         TLT     Y1,A                ;If A1<=-1/2, set FA1='-1.99'
  2084.         TST     B       #0,X0       ;Check PKS1
  2085.         JMI     <FINDSUM_R          ;If PKS1=1, FA=FA1
  2086.         NEG     A                   ; else PKS1=0, set FA=-FA1
  2087. FINDSUM_R   ADD     X1,A    Y:RSHFT+5,Y1    ;Find UGA2B=UGA2A+FA,
  2088.                                     ; get shift constant
  2089.         MOVE    A,X1
  2090.         MPY     X1,Y1,A     Y:(R7)+,X1  ;Find UGA2B>>7, get mask K22
  2091.         AND     X1,A    Y:SIGPK_R,B ;Truncate UGA2, get SIGPK
  2092.         TST     B   Y:(R6),Y0       ;Check SIGPK, get A2
  2093.         TMI     X0,A                ;If SIGPK=1, set UGA2=0
  2094.         MOVE    Y:RSHFT+7,X0        ;Get shift constant
  2095.         MPY     Y0,X0,B             ;Find A2>>7
  2096.         AND     X1,B                ;Truncate to find A2>>7
  2097.         NEG     B       #<$D0,X0    ;Find ULA2=-(A2>>7), get A2LL
  2098.         ADD     B,A     #<$30,X1    ;Find UA2=UGA2+ULA2, get A2UL
  2099.         ADD     Y0,A    Y:(R7)+,Y1  ;Find A2T=A2+UA2, get -gain (K23)
  2100.  
  2101. ;**************************************************************************
  2102. ;       LIMC
  2103. ;
  2104. ; Limit the A2 coefficient of the second order predictor.
  2105. ;
  2106. ;   |A2(k)| <= '0.75' 
  2107. ;
  2108. ; Inputs:
  2109. ;   A2T = si.ff ffff | ffff ffff | 0000 0000 (16TC)
  2110. ;
  2111. ; Outputs:
  2112. ;   A2P = Y:(R6) = si.ff ffff | ffff ffff | 0000 0000 (16TC)
  2113. ;
  2114. ;**************************************************************************
  2115.  
  2116.         CMP     X0,A    Y:(R7)+,Y0  ;Check A2P, get +gain (K24)
  2117.         TLT     X0,A                ;If A2P<-0.75, set A2P=-0.75
  2118.         CMP     X1,A    X:PKS1,B    ;Check A2P again, get PKS1=PK0**PK1
  2119.         TGT     X1,A                ;If A2P>0.75, set A2P=0.75
  2120.         MOVE    A,Y:A2P_R           ;Save A2P
  2121.         MOVE    A,Y:(R6)-           ;Save A2P to A2
  2122.  
  2123. ;**************************************************************************
  2124. ;       UPA1
  2125. ;
  2126. ; Update the A1 coefficient of the second order predictor.
  2127. ;
  2128. ; A1(k) = [1-(2**-8)] * A1(k-1)
  2129. ;           + 3 * (2**-8) * sgn[P(k)] * sgn[P(k-1)]
  2130. ;
  2131. ; Inputs:
  2132. ;   A1 = Y:(R6) = si.ff ffff | ffff ffff | 0000 0000 (16TC)
  2133. ;   SIGPK = Y:(R0) = i000 0000 | 0000 0000 | 0000 0000  (1TC)
  2134. ;   PK0 = sXXX XXXX | XXXX XXXX | 0000 0000  (1TC)
  2135. ;   PK1 = sXXX XXXX | XXXX XXXX | 0000 0000  (1TC)
  2136. ;     (Note: PKS1 has been previously calculated)
  2137. ;
  2138. ; Outputs:
  2139. ;   A1T = si.ff ffff | ffff ffff | 0000 0000 (16TC)
  2140. ;
  2141. ;**************************************************************************
  2142.  
  2143.         TST     B       Y:SIGPK_R,B ;Check PKS1, get SIGPK
  2144.         TPL     Y0,A                ;If PKS=0, set UGA1=+gain
  2145.         TMI     Y1,A                ;If PKS=1, set UGA1=-gain
  2146.         TST     B       #0,X0       ;Check SIGPK
  2147.         TMI     X0,A                ;If SIGPK=1, set UGA1=0
  2148.         MOVE    Y:(R6),X1           ;Get A1
  2149.         MOVE    Y:RSHFT+8,Y0        ;Get shift constant
  2150.         MPY     Y0,X1,B     Y:(R7)+,X0  ;Find A1>>8, get mask K25
  2151.         AND     X0,B                ;Truncate (A1>>8)
  2152.         NEG     B                   ;Find ULA1=-(A1>>8)
  2153.         ADD     B,A     #<$3C,B     ;Find UA1=UGA1+ULA1,
  2154.                                     ; get OME='1-(2**-4)'
  2155.         ADD     X1,A    Y:A2P_R,X0  ;Find A1T=A1+UA1, get A2P
  2156.  
  2157. ;**************************************************************************
  2158. ;       LIMD
  2159. ;
  2160. ; Limit the A1 coefficient of the second order predictor.
  2161. ;
  2162. ;   |A1(k)| <= [1-(2**-4)] - A2(k)
  2163. ;
  2164. ; Inputs:
  2165. ;   A1T = si.ff ffff | ffff ffff | 0000 0000 (16TC)
  2166. ;   A2P = si.ff ffff | ffff ffff | 0000 0000 (16TC)
  2167. ;
  2168. ; Outputs:
  2169. ;   A1P = Y:(R6) = si.ff ffff | ffff ffff | 0000 0000 (16TC)
  2170. ;
  2171. ;**************************************************************************
  2172.  
  2173.         SUB     X0,B                ;Find A1UL=OME-A2P
  2174.         CMP     B,A     B,X0        ;Check A1T
  2175.         TGT     X0,A                ;If A1T>A1UL, set A1P=A1UL
  2176.         NEG     B       (R2)+       ;Find A1LL=-A1UL=A2P-OME
  2177.         CMP     B,A     B,X0        ;Check A1T again
  2178.         TLT     X0,A                ;If A1T<A1LL, set A1P=A1LL
  2179.         MOVE    A1,Y:(R6)+          ;Store A1P to A1
  2180.         MOVE    (R6)+               ;Adjust coef pointer
  2181.  
  2182. ;**************************************************************************
  2183. ;       FLOATA
  2184. ;
  2185. ; Converts the quantized difference signal from 15-bit
  2186. ;   signed magnitude to floating pt. format (11FL - sign,
  2187. ;   exp, and mant stored separately)
  2188. ;
  2189. ; Inputs:
  2190. ;   DQ = siii iiii | iiii iii.0 | 0000 0000 (15SM)
  2191. ;
  2192. ; Outputs:
  2193. ;   DQ0 = (11FL)
  2194. ;    DQ0EXP = X:(R2) = 0000 0000 | 0000 0000 | 0000 eeee
  2195. ;    DQ0MANT = X:(R2+1) = 01mm mmm0 | 0000 0000 | 0000 0000
  2196. ;    DQ0S = X:(R2+2) = sXXX XXXX | XXXX XXXX | 0000 0000
  2197. ;
  2198. ;**************************************************************************
  2199.  
  2200.         MOVE    X:DQ_R,Y0           ;Get DQS
  2201.         MOVE    Y:DQMAG,A           ;Get MAG=DQMAG
  2202.         TST     A   #$000E,R0       ;Check MAG, get exponent bias (14)
  2203.         JNE     <NORMDQ_R           ;Test MAG
  2204.         MOVE    #<$40,A             ;If MAG=0 set MANT=100000,
  2205.         MOVE    #0,R0               ; and EXP=0
  2206.         JMP     <TRUNCDQ_R
  2207. NORMDQ_R    NORM    R0,A            ;If MAG!=0 do NORM iteration 13
  2208.         NORM    R0,A                ; times to find MSB of MAG
  2209.         NORM    R0,A
  2210.         NORM    R0,A
  2211.         NORM    R0,A
  2212.         NORM    R0,A
  2213.         NORM    R0,A
  2214.         NORM    R0,A
  2215.         NORM    R0,A
  2216.         NORM    R0,A
  2217.         NORM    R0,A
  2218.         NORM    R0,A
  2219.         NORM    R0,A
  2220. ;   A1 = 01?? ???? | ???? ???0 | 0000 0000 = normalized MAG (A2=A0=0)
  2221. ;   R0 = 0000 0000 | 0000 eeee = exponent of normalized MAG
  2222.  
  2223. TRUNCDQ_R   MOVE    #<$7E,X0        ;Get mask
  2224.         AND     X0,A    R0,X:(R2)+  ;Truncate MANT to 6 bits,
  2225.                                     ; save EXP to DQ1EXP
  2226. ;   A1 = 01mm mmm0 | 0000 0000 | 0000 0000  (A2=A0=0)
  2227.         MOVE    A1,X:(R2)+          ;Save MANT to DQ1MANT
  2228.         MOVE    Y0,X:(R2)+          ;Save DQ to DQ1S
  2229.  
  2230. ;**************************************************************************
  2231. ;       FLOATB
  2232. ;
  2233. ; Converts the reconstructed signal from 16-bit two's 
  2234. ;   complement to floating pt. format (11FL - sign,
  2235. ;   exp, and mant stored separately)
  2236. ;
  2237. ; Inputs:
  2238. ;   SR = siii iiii | iiii iiii. | 0000 0000  (16TC)
  2239. ;
  2240. ; Outputs:
  2241. ;   SR0 = (11FL)
  2242. ;    SR0EXP = X:(R2) = 0000 0000 | 0000 0000 | 0000 eeee
  2243. ;    SR0MANT = X:(R2+1) = 01mm mmm0 | 0000 0000 | 0000 0000
  2244. ;    SR0S = X:(R2+2) = sXXX XXXX | XXXX XXXX | 0000 0000
  2245. ;
  2246. ;**************************************************************************
  2247.  
  2248.         MOVE    #15,N2
  2249.         MOVE    Y:SR_R,B            ;Get SR
  2250.         MOVE    (R2)+N2             ;Adjust data pointer
  2251.         ABS     B       B,Y0        ;Find MAG=|SR|, save SRS
  2252.         TST     B   #$000F,R0       ;Load exponent bias
  2253.         JNE     <NORMSR_R           ;Test MAG
  2254.         MOVE    #<$40,B             ;If MAG=0 set MANT=100000,
  2255.         MOVE    #0,R0               ; and EXP=0
  2256.         JMP     <TRUNCSR_R
  2257. NORMSR_R    NORM    R0,B            ;If MAG!=0 do NORM iteration 14
  2258.         NORM    R0,B                ; times to find MSB of MAG
  2259.         NORM    R0,B
  2260.         NORM    R0,B
  2261.         NORM    R0,B
  2262.         NORM    R0,B
  2263.         NORM    R0,B
  2264.         NORM    R0,B
  2265.         NORM    R0,B
  2266.         NORM    R0,B
  2267.         NORM    R0,B
  2268.         NORM    R0,B
  2269.         NORM    R0,B
  2270.         NORM    R0,B
  2271. ;   A1 = 01?? ???? | ???? ???0 | 0000 0000 = normalized MAG (A2=A0=0)
  2272. ;   R0 = 0000 0000 | 0000 eeee = exponent of normalized MAG
  2273.  
  2274. TRUNCSR_R   AND     X0,B    R0,X:(R2)+  ;Truncate MANT to 6 bits,
  2275.                                     ; save EXP to SR1EXP
  2276. ;   A1 = 01mm mmm0 | 0000 0000 | 0000 0000  (A2=A0=0)
  2277.         MOVE    B1,X:(R2)+          ;Save MANT to SR1MANT
  2278.         MOVE    Y0,X:(R2)+          ;Save SR to SR1S
  2279.         MOVE    #3,N2
  2280.         MOVE    Y:A2P_R,B           ;Get A2P
  2281.         MOVE    (R2)+N2             ;Adjust data pointer
  2282.  
  2283. ;**************************************************************************
  2284. ;       TONE
  2285. ;
  2286. ; Partial band signal detection
  2287. ;
  2288. ; TD(k) = 1 if A2(k) < -0.71875
  2289. ;         0 otherwise
  2290. ;
  2291. ; Inputs:
  2292. ;   A2P = si.ff ffff | ffff ffff | 0000 0000  (16TC)
  2293. ;
  2294. ; Output:
  2295. ;   TDP = i000 0000 | 0000 0000 | 0000 0000  (1TC)
  2296. ;
  2297. ;**************************************************************************
  2298.  
  2299.         CLR     A   #<$D2,X0        ;Get '-.71875', set TDP=0
  2300.         CMP     X0,B    #<$80,X1    ;Check A2P, get '1'
  2301.         TLT     X1,A                ;If A2P<-.71875 set TDP=1, else TDP=0
  2302.         MOVE    A1,Y:TDP_R          ;Save TDP
  2303.         MOVE    A1,Y:TD_R           ;Save TDP to TD
  2304.  
  2305. ;**************************************************************************
  2306. ;       TRIGB
  2307. ;
  2308. ; Predictor trigger block
  2309. ;
  2310. ; If TR(k) = 1, An(k)=Bn(k)=TD(k)=0
  2311. ;
  2312. ; Inputs:
  2313. ;   TR = i000 0000 | 0000 0000 | 0000 0000  (1TC)
  2314. ;   BnP = si.ff ffff | ffff ffff | 0000 0000  (16TC)
  2315. ;   AnP = si.ff ffff | ffff ffff | 0000 0000  (16TC)
  2316. ;   TDP = i000 0000 | 0000 0000 | 0000 0000  (1TC)
  2317. ;
  2318. ; Output:
  2319. ;   BnR = si.ff ffff | ffff ffff | 0000 0000  (16TC)
  2320. ;   AnR = si.ff ffff | ffff ffff | 0000 0000  (16TC)
  2321. ;   TDR = i000 0000 | 0000 0000 | 0000 0000  (1TC)
  2322. ;
  2323. ;**************************************************************************
  2324.  
  2325.         MOVE    Y:TR_R,B            ;Get TR
  2326.         TST     B       #0,A        ;Test TR
  2327.         JEQ     <FUNCTF_R           ;If TR=0 continue
  2328.         MOVE    A,Y:TD_R            ;If TR=1, set TDR=0,
  2329.         MOVE    A,Y:(R6)+           ; and B1-B6,A1,A2=0
  2330.         MOVE    A,Y:(R6)+
  2331.         MOVE    A,Y:(R6)+
  2332.         MOVE    A,Y:(R6)+
  2333.         MOVE    A,Y:(R6)+
  2334.         MOVE    A,Y:(R6)+
  2335.         MOVE    A,Y:(R6)+
  2336.         MOVE    A,Y:(R6)+
  2337.  
  2338. ;**************************************************************************
  2339. ;       FUNCTF
  2340. ;
  2341. ; Maps quantizer output I into F(I) function
  2342. ;
  2343. ;  |I(k)|  | 7 | 6 | 5 | 4 | 3 | 2 | 1 | 0 |
  2344. ; ---------+---+---+---+---+---+---+---+---+
  2345. ;  F[I(k)] | 7 | 3 | 1 | 1 | 1 | 0 | 0 | 0 |
  2346. ;
  2347. ; Inputs:
  2348. ;   I = siii 0000 | 0000 0000 | 0000 0000
  2349. ;
  2350. ; Output:
  2351. ;   FI = 0iii. 0000 | 0000 0000 | 0000 0000  (3SM)
  2352. ;   IMAG
  2353. ;
  2354. ;**************************************************************************
  2355.  
  2356. FUNCTF_R    MOVE    #<$20,X0
  2357.         MOVE    X:IMAG,A            ;Get |I|
  2358.         CMP     X0,A    #<$50,X0    ;Test for |I|<=2
  2359.         JLE     <RANGE0_R
  2360.         CMP     X0,A    #<$60,X0    ;Test for 3<=|I|<=5
  2361.         JLE     <RANGE1_R
  2362.         CMP     X0,A                ;Test for |I|=6
  2363.         JEQ     <RANGE3_R
  2364.         MOVE    #<$70,A             ;|I|=7, set F[I]=7
  2365.         JMP     <FILTA_R
  2366. RANGE3_R    MOVE    #<$30,A         ;|I|=6, set F[I]=3
  2367.         JMP     <FILTA_R
  2368. RANGE1_R    MOVE    #<$10,A         ;|I|=3,4,or 5, set F[I]=1
  2369.         JMP     <FILTA_R
  2370. RANGE0_R    CLR     A               ;|I|=0,1,or 2, set F[I]=0
  2371.  
  2372. ;**************************************************************************
  2373. ;       FILTA
  2374. ;
  2375. ; Update short term average of F(I)
  2376. ;
  2377. ; DMS(k) = (1 - 2**(-5)) * DMS(k-1) + 2**(-5) * F[I(k)]
  2378. ;
  2379. ; Inputs:
  2380. ;   FI = 0iii. 0000 | 0000 0000 | 0000 0000  (3SM)
  2381. ;   DMS = 0iii. ffff | ffff f000 | 0000 0000  (12SM)
  2382. ;
  2383. ; Output:
  2384. ;   DMSP = 0iii. ffff | ffff f000 | 0000 0000  (12SM)
  2385. ;
  2386. ;**************************************************************************
  2387.  
  2388. FILTA_R MOVE    Y:DMS_R,Y0          ;Get DMS
  2389.         SUB     Y0,A    A,B         ;Find DIF=FI-DMS, save FI
  2390.         MOVE    A,X0    Y:(R7)+,Y1  ;Save DIF, get mask K26
  2391.         MPY     X0,Y1,A Y:(R7)+,X0  ;Find DIFSX=DIF>>5, get mask K27
  2392.         AND     X0,A    Y:DML_R,Y1  ;Truncate DIFSX, get DML
  2393.         ADD     Y0,A    Y:RSHFT+7,X1    ;Find DMSP=DIFSX+DMS
  2394.  
  2395. ;**************************************************************************
  2396. ;       FILTB
  2397. ;
  2398. ; Update long term average of F(I)
  2399. ;
  2400. ; DML(k) = (1 - 2**(-7)) * DML(k-1) + 2**(-7) * F[I(k)]
  2401. ;
  2402. ; Inputs:
  2403. ;   FI = 0iii. 0000 | 0000 0000 | 0000 0000  (3SM)
  2404. ;   DML = 0iii. ffff | ffff fff0 | 0000 0000  (14SM)
  2405. ;
  2406. ; Output:
  2407. ;   DMLP = 0iii. ffff | ffff fff0 | 0000 0000  (14SM)
  2408. ;
  2409. ;**************************************************************************
  2410.  
  2411.         SUB     Y1,B    A1,Y:DMS_R  ;Find DIF=FI-DML
  2412.         MOVE    B1,X0
  2413.         MPY     X0,X1,B Y:(R7)+,X0  ;Find DFISX=DIF>>7, get mask K28
  2414.         AND     X0,B                ;Truncate DIFSX
  2415.         ADD     Y1,B    Y:RSHFT+3,X1    ;Find DMLP=DIFSX+DML
  2416.  
  2417. ;**************************************************************************
  2418. ;       SUBTC
  2419. ;
  2420. ; Compute magnitude of the difference of short and long
  2421. ;  term functions of quantizer output sequence and then
  2422. ;  perform threshold comparison for quantizing speed control
  2423. ;  parameter.
  2424. ;
  2425. ; AX = 1  if Y>=3, TDP=1, & |DMSP-DMLP|>(2**-3)*DMLP
  2426. ;    = 0  otherwise
  2427. ;
  2428. ; Input:
  2429. ;   Y = 0iii i.fff | ffff ff00 | 0000 0000  (13SM)
  2430. ;   DMSP = 0iii. ffff | ffff f000 | 0000 0000  (12SM)
  2431. ;   DMLP = 0iii. ffff | ffff fff0 | 0000 0000  (14SM)
  2432. ;   TDP = i000 0000 | 0000 0000 | 0000 0000  (1TC)
  2433. ;
  2434. ; Output:
  2435. ;   AX = 0i0.0 0000 | 0000 0000 | 0000 0000  (1SM)
  2436. ;
  2437. ;**************************************************************************
  2438.  
  2439.         SUB     B,A     B1,Y:DML_R  ;Find DIF=DMSP-DMLP, save DML
  2440.         ABS     A       B1,Y0       ;Find DIFM=|DIF|
  2441.         MPY     X1,Y0,B     #<$18,Y0    ;Find DTHR=DMLP>>3, get '3'
  2442.         AND     X0,B    #<$40,X0    ;Truncate DTHR, get '1'
  2443.         CMP     B,A     #0,B        ;Compare DIFM & DTHR, set AX=0
  2444.         TGE     X0,B                ;If DIFM>=DTHR set AX=1
  2445.         MOVE    Y:TDP_R,A           ;Get TDP
  2446.         TST     A       X:Y_R,A     ;Check TDP, get Y
  2447.         TNE     X0,B                ;If TDP!=0 set AX=1
  2448.         CMP     Y0,A    X:AP_R,X1   ;Check for Y<"3", get AP
  2449.         TLT     X0,B                ;If Y<"3" set AX=1
  2450.  
  2451. ;**************************************************************************
  2452. ;       FILTC
  2453. ;
  2454. ; Low pass filter of speed control parameter
  2455. ;
  2456. ; AP(k) = (1-2**(-4)) * AP(k-1) + AX
  2457. ;
  2458. ; Inputs:
  2459. ;   AX = 0i0.0 0000 | 0000 0000 | 0000 0000  (1SM)
  2460. ;   AP = 0ii.f ffff | fff0 0000 | 0000 0000  (10SM)
  2461. ;
  2462. ; Outputs:
  2463. ;   APP = 0ii.f ffff | fff0 0000 | 0000 0000  (10SM)
  2464. ;
  2465. ;**************************************************************************
  2466.  
  2467.         SUB     X1,B    Y:RSHFT+4,Y0    ;Find DIF=AX-AP
  2468.         MOVE    B1,X0
  2469.         MPY     X0,Y0,A     Y:(R7)+,X0  ;Find DIFSX=DIF>>4, get K29
  2470.         AND     X0,A    Y:TR_R,B    ;Truncate DIFSX, get TR
  2471.         ADD     X1,A    #<$20,X0    ;Find APP=DIFSX+AP, get '1'
  2472.  
  2473. ;**************************************************************************
  2474. ;       TRIGA
  2475. ;
  2476. ; Speed control trigger block
  2477. ;
  2478. ; AP(k) = AP(k) if TR(k)=0
  2479. ;       =  1    if TR(k)=1
  2480. ;
  2481. ; Inputs:
  2482. ;   TR = i000 0000 | 0000 0000 | 0000 0000  (1TC)
  2483. ;   APP = 0ii.f ffff | fff0 0000 | 0000 0000  (10SM)
  2484. ;
  2485. ; Outputs:
  2486. ;   APR = 0ii.f ffff | fff0 0000 | 0000 0000  (10SM)
  2487. ;
  2488. ;**************************************************************************
  2489.  
  2490.         TST     B   X:IMAG,X1       ;Check TR, get IMAG
  2491.         TMI     X0,A                ;If TR=1 set APR=1, else APR=APP
  2492.         MOVE    A1,X:AP_R           ;Save APR to AP
  2493.  
  2494. ;**************************************************************************
  2495. ;       FUNCTW
  2496. ;
  2497. ; Map quantizer output into logarithmic version of scale
  2498. ;  factor multiplier
  2499. ;
  2500. ;  |I(k)|  |  7  |  6  |  5  |  4  |  3  |  2  |  1  |  0  |
  2501. ; ---------+-----+-----+-----+-----+-----+-----+-----+-----+
  2502. ;   W(I)   |70.13|22.19|12.38| 7.00| 4.00| 2.56| 1.13|-0.75|
  2503. ;
  2504. ; Inputs:
  2505. ;   I = siii. 0000 | 0000 0000 | 0000 0000  (ADPCM format)
  2506. ;
  2507. ; Outputs:
  2508. ;   WI = siii iiii. | ffff 0000 | 0000 0000  (12TC)
  2509. ;
  2510. ;**************************************************************************
  2511.  
  2512.         MOVE    Y:RSHFT+20,X0       ;Get shift constant
  2513.         MPY     X0,X1,A     #WIBASE,R0  ;Shift IM=IMAG for lookup,
  2514.                                     ; load lookup table base
  2515.         MOVE    A1,N0               ;Load IM as offset
  2516.         MOVE    Y:RSHFT+3,X1        ;Get shift constant
  2517.         MOVE    X:Y_R,Y0            ;Get Y
  2518.         MPY     Y0,X1,B     X:(R0+N0),A ;Shift Y>>3,
  2519.                                     ; get WI from lookup table
  2520.  
  2521. ;**************************************************************************
  2522. ;       FILTD
  2523. ;
  2524. ; Update of fast quantizer scale factor
  2525. ;
  2526. ; YU(k) = (1 - 2**(-5)) * Y(k) + 2**(-5) * W[I(k)]
  2527. ;
  2528. ; Inputs:
  2529. ;   WI =  siii iiii. | ffff 0000 | 0000 0000  (12TC)
  2530. ;   Y = 0iii i.fff | ffff ff00 | 0000 0000  (13SM)
  2531. ;
  2532. ; Outputs:
  2533. ;   YUT = 0iii i.fff | ffff ff00 | 0000 0000  (13SM)
  2534. ;
  2535. ;**************************************************************************
  2536.  
  2537.         SUB     B,A                 ;Find DIF=WI-Y
  2538.         ASR     A                   ;Find DIFSX=DIF>>5 (actually DIF>>2)
  2539.         ASR     A   Y:(R7)+,X0      ;Get mask K30
  2540.         AND     X0,A                ;Truncate DIFSX
  2541.         ADD     Y0,A    #<$50,X0    ;Find YUT=DIFSX+Y,
  2542.                                     ; get upper limit '10'
  2543.  
  2544. ;**************************************************************************
  2545. ;       LIMB
  2546. ;
  2547. ; Limit quantizer scale factor
  2548. ;
  2549. ; 1.06 <= YU(k) <= 10.00
  2550. ;
  2551. ; Inputs:
  2552. ;   YUT = 0iii i.fff | ffff ff00 | 0000 0000  (13SM)
  2553. ;
  2554. ; Outputs:
  2555. ;   YUP = 0iii i.fff | ffff ff00 | 0000 0000  (13SM)
  2556. ;
  2557. ;**************************************************************************
  2558.  
  2559.         CMP     X0,A    Y:(R7)+,X1  ;Check for YU>10,
  2560.                                     ; get lower limit '1.06' (K31)
  2561.         TGT     X0,A                ;If YU>10 set YU=10
  2562.         CMP     X1,A    Y:YL_R,Y1   ;Check for YU<1.06, get YL
  2563.         TLT     X1,A                ;If YU<1.06 set YU=1.06
  2564.  
  2565. ;**************************************************************************
  2566. ;       FILTE
  2567. ;
  2568. ; Update of slow quantizer scale factor
  2569. ;
  2570. ; YL(k) = (1 - 2**(-6)) * YL(k-1) + 2**(-6) * YU(k)
  2571. ;
  2572. ; Inputs:
  2573. ;   YUP = 0iii i.fff | ffff ff00 | 0000 0000  (13SM)
  2574. ;   YL = 0iii i.fff | ffff ffff | ffff 0000  (19SM)
  2575. ;
  2576. ; Outputs:
  2577. ;   YLP = 0iii i.fff | ffff ffff | ffff 0000  (19SM)
  2578. ;
  2579. ;**************************************************************************
  2580.  
  2581.         TFR     Y1,B    A1,Y:YU_R   ;Move YL, save YUP
  2582.         NEG     B   Y:(R7)+,Y0      ;Find -YL, save YL, get mask K32
  2583.         AND     Y0,B    #CONST4,R7  ;Truncate -YL (-YL>>6),
  2584.                                     ; adjust constant pointer
  2585.         ADD     B,A     Y:RSHFT+6,Y0    ;Find DIF=YUP+(-YL>>6)
  2586.         MOVE    A1,X1
  2587.         MPY     Y0,X1,A     #$002100,Y0     ;Find DIFSX>>6, get bias
  2588.         ADD     Y1,A    Y:LAW,B     ;Find YLP=DIFSX+YL
  2589.         MOVE    A1,Y:YL_R           ;Save YL
  2590.  
  2591. ;**************************************************************************
  2592. ;       COMPRESS
  2593. ;
  2594. ; Convert from uniform PCM to A-law or mu-law PCM (according to
  2595. ;   Recommendation G.711). For further details see Motorola
  2596. ;   application bulletin "Logarithmic/Linear Conversion
  2597. ;   Routines for DSP56000/1".
  2598. ;
  2599. ; Input:
  2600. ;   SR = siii iiii | iiii iiii. | 0000 0000  (16TC)
  2601. ;
  2602. ; Output:
  2603. ;   SP = psss qqqq | 0000 0000 | 0000 0000 (PCM log format)
  2604. ;
  2605. ;**************************************************************************
  2606.  
  2607.         TST     B       Y:SR_R,A    ;Adjust constant pointer
  2608.         JNE     <ALAW_R
  2609.  
  2610. ; Linear to log routine for mu-law
  2611.         ABS     A       A,B         ;Find |SR|, save sign
  2612.         ADD     Y0,A                ;Add bias
  2613.         ASL     A   #TAB+7,R0       ;Shift << 2, get seg ptr
  2614.         ASL     A   X:TAB+3,X0      ; and get max. word
  2615.         TES     X0,A                ;If overflow in extension
  2616.                                     ; set the maximum PCM word
  2617.         NORM    R0,A                ;Find MSB of data
  2618.         NORM    R0,A
  2619.         NORM    R0,A
  2620.         NORM    R0,A
  2621.         NORM    R0,A
  2622.         NORM    R0,A
  2623.         NORM    R0,A
  2624.         ASL     A       #<$20,Y0
  2625.         LSL     B       A1,X0
  2626.         MPY     X0,Y0,A     X:(R0),X1
  2627.         AND     X1,A
  2628.         ROR     A
  2629.         NOT     A       #<$FF,X0
  2630.         AND     X0,A
  2631.         MOVE    A1,A
  2632.         JMP     <SAVESP_R
  2633.  
  2634. ; Linear to log routine for A-law
  2635. ALAW_R  ABS     A       A,B         ;Find |SR|, save sign
  2636.         TST     B       #$000100,X0
  2637.         JPL     <NOSUB_R
  2638.         SUB     X0,A
  2639. NOSUB_R MOVE    #$7FFE00,X0
  2640.         AND     X0,A
  2641.         ASL     A   #TAB+7,R0       ;Shift << 2, get seg ptr
  2642.         ASL     A   X:TAB+3,X0      ; and get max. word
  2643.         TES     X0,A                ;If overflow in extension
  2644.                                     ; set the maximum PCM word
  2645.         NORM    R0,A                ;Find MSB of data
  2646.         NORM    R0,A
  2647.         NORM    R0,A
  2648.         NORM    R0,A
  2649.         NORM    R0,A
  2650.         NORM    R0,A
  2651.         JNR     <SEGOK_R
  2652.         MOVE    (R0)-
  2653. SEGOK_R LSL     A       #<$20,Y0
  2654.         LSL     B       A1,X0
  2655.         MPY     X0,Y0,A     X:(R0),X1
  2656.         AND     X1,A
  2657.         ROR     A       #<$D5,Y1
  2658.         EOR     Y1,A    #<$FF,X0    ;Invert even bits & sign
  2659.         AND     X0,A
  2660.         MOVE    A1,A
  2661. SAVESP_R    MOVE    A1,X:SP_R
  2662.  
  2663. ;**************************************************************************
  2664. ;       EXPAND
  2665. ;
  2666. ; Convert A-law or mu-law PCM to uniform PCM (according to
  2667. ;   Recommendation G.711). For further details see Motorola
  2668. ;   application bulletin "Logarithmic/Linear Conversion
  2669. ;   Routines for DSP56000/1".
  2670. ;
  2671. ; Input:
  2672. ;   SP = psss qqqq | 0000 0000 | 0000 0000 (PCM log format)
  2673. ;
  2674. ; Output:
  2675. ;   SLX = siii iiii | iiii ii.00 | 0000 0000  (14TC)
  2676. ;
  2677. ;**************************************************************************
  2678.  
  2679.         MOVE    A,X0        Y:(R7)+,Y1  ;Get shift constant K4
  2680.         MPY     X0,Y1,A     Y:(R7)+,X1  ;Shift S to 8 lsb's of A1, get K5
  2681.         AND     X1,A    Y:SE_R,B    ;Mask off sign of S, get SE
  2682.         ASR     B       A1,N3       ;Sign extend SE, load |S| as offset
  2683.         CMPM    Y1,A                ;Check sign of S
  2684.         MOVE    X:(R3+N3),A         ;Lookup |SLX| from ROM table
  2685.         JGE     <SUBTA_R            ;If S=0, SLX=|SLX|
  2686.         NEG     A                   ;If S=1, SLX=-|SLX|
  2687.  
  2688. ;**************************************************************************
  2689. ;       SUBTA
  2690. ;
  2691. ; Compute difference signal by subtracting signal estimate
  2692. ;       from input signal
  2693. ;
  2694. ;   DX(k) = SLX(k) - SE(k)
  2695. ;
  2696. ; Inputs:
  2697. ;   SLX = siii iiii | iiii ii.00 | 0000 0000  (14TC) 
  2698. ;   SE = siii iiii | iiii iii.0 | 0000 0000  (15TC)
  2699. ;
  2700. ; Output:
  2701. ;   DX = siii iiii | iiii iiii. | 0000 0000  (16TC)
  2702. ;**************************************************************************
  2703.  
  2704. SUBTA_R ASR     A       Y:(R7)+,X1  ;Sign extend SLX, get mask K6
  2705.         ASR     A       #$000E,R0   ;Sign extend SE again, get exp bias (14)
  2706.         SUB     B,A     X:Y_R,B     ;Find DX=SLX-SE, get Y
  2707.  
  2708. ;**************************************************************************
  2709. ;       LOG
  2710. ;
  2711. ; Convert difference signal from the linear to the log
  2712. ;   domain
  2713. ;
  2714. ; Input:
  2715. ;   DX = siii iiii | iiii iiii. | 0000 0000  (16TC)
  2716. ;
  2717. ; Outputs:
  2718. ;   DLX = 0iii i.fff | ffff 0000 | 0000 0000  (11SM)
  2719. ;   DSX = sXXX XXXX | XXXX XXXX | 0000 0000  (1TC)
  2720. ;
  2721. ;**************************************************************************
  2722.  
  2723.         ABS     A   A,Y1            ;Find DQM=|D|, save DSX to Y1
  2724.         JNE     <NORMEXP_R          ;Check for DQM=0
  2725.         CLR     A       (R7)+       ;If DQM=0 set DL=0,
  2726.         MOVE    Y:(R7),X0           ; get mask K8,
  2727.         JMP     <SUBTB_R            ; and continue
  2728. NORMEXP_R   NORM    R0,A            ;If DQM!=0, do norm iteration
  2729.         NORM    R0,A                ; 14 times to find MSB of DQM
  2730.         NORM    R0,A
  2731.         NORM    R0,A
  2732.         NORM    R0,A
  2733.         NORM    R0,A
  2734.         NORM    R0,A
  2735.         NORM    R0,A
  2736.         NORM    R0,A
  2737.         NORM    R0,A
  2738.         NORM    R0,A
  2739.         NORM    R0,A
  2740.         NORM    R0,A
  2741.         NORM    R0,A
  2742. ;   A1 = 01?? ???? | ???? ???? | 0000 0000 = normalized DQM  (A2=A0=0)
  2743. ;   R0 = 0000 0000 | 0000 eeee = exponent of normalized DQM
  2744.  
  2745. ;   Get rid of leading "1" in normalized DQM
  2746. ;   Truncate mantissa to 7 bits and combine with exponent
  2747.         AND     X1,A    Y:LSHFT-19,X0   ;Truncate MANT, get EXP shift
  2748. ;   A1 = 00mm mmmm | m000 0000 | 0000 0000 (A2=A0=0)
  2749.         MOVE    R0,X1               ;Move EXP to X1
  2750.         MPY     X0,X1,A     A,X1    Y:(R7)+,Y0 ;Shift EXP<<19, save MANT to X1,
  2751.                                     ; get mask K7
  2752.         MOVE    A0,A                ;Move EXP to A1
  2753. ;   A1 = 0eee e000 | 0000 0000 | 0000 0000 (A2=A0=0)
  2754.         MAC     Y0,X1,A     Y:(R7),X0   ;Shift MANT>>3 & combine with EXP,
  2755.                                         ; get mask K8
  2756. ;   A1 = 0eee e.mmm | mmmm 0000 | 0000 0000  (A2=A0=0)
  2757. ;      = 0iii i.fff | ffff 0000 | 0000 0000  (A2=A0=0)
  2758.  
  2759. ;**************************************************************************
  2760. ;       SUBTB
  2761. ;
  2762. ; Scale log version of difference signal by subtracting
  2763. ;   scale factor
  2764. ;
  2765. ; DLNX = DLX - Y
  2766. ;
  2767. ; Inputs:
  2768. ;   DLX = 0iii i.fff | ffff 0000 | 0000 0000  (11SM)
  2769. ;   Y = 0iii i.fff | ffff ff00 | 0000 0000  (13SM)
  2770. ;
  2771. ; Output:
  2772. ;   DLNX = siii i.fff | ffff 0000 | 0000 0000 (12TC)
  2773. ;
  2774. ;**************************************************************************
  2775.  
  2776. SUBTB_R AND     X0,B    #QUANTAB,R0     ;Truncate Y to 11 bits (Y>>2),
  2777.                                         ; get quantization table base
  2778.         SUB     B,A     #>QUANTAB+2,X1  ;Find DLNX=DLX-Y
  2779.  
  2780. ;**************************************************************************
  2781. ;       SYNC
  2782. ;
  2783. ; Re-encode output PCM sample in decoder for synchronous
  2784. ;   tandem coding
  2785. ;
  2786. ; Inputs:
  2787. ;   I = siii 0000 | 0000 0000 | 0000 0000 (ADPCM format)
  2788. ;   SP = psss qqqq | 0000 0000 | 0000 0000 (PCM log format)
  2789. ;   DLNX = siii i.fff | ffff 0000 | 0000 0000 (12TC)
  2790. ;   DSX = sXXX XXXX | XXXX XXXX | 0000 0000  (1TC)
  2791. ;
  2792. ; Output:
  2793. ;   SD = psss qqqq | 0000 0000 | 0000 0000 (PCM log format)
  2794. ;
  2795. ;**************************************************************************
  2796.  
  2797.         MOVE    X:(R0)+,X0          ;Get quan table value
  2798. TSTDLN_R    CMP     X0,A    X:(R0)+,X0  ;Compare to DLNX
  2799.         JGE     <TSTDLN_R           ;If value<DLNX try next range
  2800.         MOVE    R0,A                ;When range found...
  2801.                                     ; subtract pointer from
  2802.         SUB     X1,A    Y:LSHFT-19,X0   ; base to get |ID|  
  2803. ;   A1 = 0000 0000 | 0000 0000 | 0000 0iii (A2=A0=0)
  2804.         MOVE    A1,X1
  2805.         MPY     X0,X1,A     Y1,B    ;Shift |ID|<<19, result is
  2806.                                     ; in A0, move DSX into B
  2807. ;   A0 = 00ii i000 | 0000 0000 | 0000 0000
  2808.         MOVE    A0,A
  2809. ;   A1 = 00ii i000 | 0000 0000 | 0000 0000 (A2=A0=0)
  2810.         TST     A       #<$78,X0    ;Check |ID|, get invert mask
  2811.         JEQ     <INVERT_R           ;If |ID|=0 invert bits
  2812.         TST     B                   ;If |ID|!=0, check DSX
  2813.         JPL     <IOUT_R             ;If DSX=1 don't invert |ID|
  2814. INVERT_R    EOR     X0,A            ;If DSX=0 or |ID|=0,
  2815.                                     ; invert |ID|
  2816. IOUT_R  MOVE    #<$40,X0
  2817.         EOR     X0,A    X:I_R,B     ;Invert MSB of ID, get I
  2818.         TST     B       A1,A        ;Adjust sign extension, check IS
  2819.  
  2820.         JMI     <ANDW7_R            ;If IS=1, AND with 7
  2821.         MOVE    #<$80,X0            ;If IS=0,
  2822.         EOR     X0,B                ; find IM=I+8
  2823.         JMP     <FIXS_R
  2824. ANDW7_R MOVE    #<$70,X0
  2825.         AND     X0,B                ;Find IM=I&7
  2826.  
  2827. FIXS_R  LSR     B
  2828.         MOVE    B1,B
  2829. ;   A1 = 0iii i000 | 0000 0000 | 0000 0000 (A2=A0=0)
  2830. ;   B1 = 0iii i000 | 0000 0000 | 0000 0000 (B2=B0=0)
  2831.         SUB     B,A     Y:LAW,B
  2832.         TST     B
  2833.         JNE     <ALAWDEC_R
  2834.  
  2835.         TST     A       X:SP_R,A    ;Compare ID and IM, get SP
  2836.         JEQ     <SAVESD_R           ;If ID=IM, SD=SP
  2837.         JLT     <SPPLUS_R           ;If ID<IM, SD=SP+
  2838.                                     ;Else ID>IM, SD=SP-
  2839.         TST     A       #<$80,X0
  2840.         JEQ     <SAVESD_R           ;If SP=0, SP-=SP
  2841.         CMP     X0,A    #<$FF,X0
  2842.         JEQ     <INCSP_R            ;If SP=$80, SP-=SP+1
  2843.         CMP     X0,A    #<$7F,X0
  2844.         JEQ     <SETNEG1_R          ;If SP=$FF, SP-=$7E
  2845.         CMP     X0,A
  2846.         JEQ     <DECSP_R            ;If SP=$7F, SP-=SP-1
  2847.         TST     A
  2848.         JPL     <DECSP_R            ;Else if SPS=1, SP-=SP-1
  2849.         JMP     <INCSP_R            ;Else SPS=0, SP-=SP+1
  2850.  
  2851. SPPLUS_R    TST     A       #<$80,X0
  2852.         JEQ     <INCSP_R            ;If SP=0, SP+=SP+1
  2853.         CMP     X0,A    #<$FF,X0
  2854.         JEQ     <SAVESD_R               ;If SP=$80, SP+=SP
  2855.         CMP     X0,A    #<$7F,X0
  2856.         JEQ     <DECSP_R            ;If SP=$FF, SP+=SP-1
  2857.         CMP     X0,A
  2858.         JEQ     <SET1_R             ;If SP=$7F, SP+=$FE
  2859.         TST     A
  2860.         JPL     <INCSP_R            ;Else if SPS=1, SP+=SP+1
  2861.         JMP     <DECSP_R            ;Else SPS=0, SP+=SP-1
  2862.  
  2863. INCSP_R MOVE    #<$01,X0
  2864.         ADD     X0,A                ;Find SD=SP+1
  2865.         JMP     <SAVESD_R
  2866. DECSP_R MOVE    #<$01,X0
  2867.         SUB     X0,A                ;Find SD=SP-1
  2868.         JMP     <SAVESD_R
  2869. SET1_R  MOVE    #<$FE,A             ;Find SD=$FE
  2870.         JMP     <SAVESD_R
  2871. SETNEG1_R   MOVE    #<$7E,A             ;Find SD=$7E
  2872.         JMP     <SAVESD_R
  2873.  
  2874.  
  2875. ALAWDEC_R   MOVE    A,B
  2876.         MOVE    X:SP_R,A                    ;Get SP
  2877.         MOVE    #<$55,X0
  2878.         EOR     X0,A
  2879.         TST     B
  2880.         JEQ     <INVEVEN_R          ;If ID=IM, SD=SP
  2881.         JLT     <SPPLUSA_R          ;If ID<IM, SD=SP+
  2882.                                     ;Else ID>IM, SD=SP-
  2883.         TST     A       #<$80,X0
  2884.         JEQ     <INCSPA_R           ;If SP=0, SP-=SP+1
  2885.         CMP     X0,A    #<$FF,X0
  2886.         JEQ     <SETNEG0_R          ;If SP=$80, SP-=0
  2887.         CMP     X0,A    #<$7F,X0
  2888.         JEQ     <DECSPA_R               ;If SP=$FF, SP-=SP-1
  2889.         CMP     X0,A
  2890.         JEQ     <INVEVEN_R          ;If SP=$7F, SP-=SP
  2891.         TST     A
  2892.         JMI     <DECSPA_R           ;Else if SPS=0, SP-=SP-1
  2893.         JMP     <INCSPA_R           ;Else SPS=1, SP-=SP+1
  2894.  
  2895. SPPLUSA_R   TST     A       #<$80,X0
  2896.         JEQ     <SET0_R             ;If SP=0, SP+=$80
  2897.         CMP     X0,A    #<$FF,X0
  2898.         JEQ     <INCSPA_R           ;If SP=$80, SP+=SP+1
  2899.         CMP     X0,A    #<$7F,X0
  2900.         JEQ     <INVEVEN_R          ;If SP=$FF, SP+=SP
  2901.         CMP     X0,A
  2902.         JEQ     <DECSPA_R           ;If SP=$7F, SP+=SP-1
  2903.         TST     A
  2904.         JMI     <INCSPA_R           ;Else if SPS=0, SP+=SP+1
  2905.         JMP     <DECSPA_R           ;Else SPS=1, SP+=SP-1
  2906.  
  2907. INCSPA_R    MOVE    #<$01,X0
  2908.         ADD     X0,A                ;Find SD=SP+1
  2909.         JMP     <INVEVEN_R
  2910. DECSPA_R    MOVE    #<$01,X0
  2911.         SUB     X0,A                ;Find SD=SP-1
  2912.         JMP     <INVEVEN_R
  2913. SET0_R  MOVE    #<$80,A             ;Find SD=$80
  2914.         JMP     <INVEVEN_R
  2915. SETNEG0_R   CLR     A                   ;Find SD=0
  2916. INVEVEN_R   MOVE    #<$55,X0
  2917.         EOR     X0,A
  2918.     
  2919. SAVESD_R    MOVE    #2,X0
  2920.         JSR     $E004
  2921.  
  2922.         MOVE    R2,X:DATAPTR_R
  2923.  
  2924.         JMP     <ENCODE
  2925.  
  2926. ;**************************************************************************
  2927. ;       INIT
  2928. ;
  2929. ; Initialize program variables, transfer data tables to X and Y
  2930. ; memory, and set up registers
  2931. ;
  2932. ;**************************************************************************
  2933.  
  2934. INIT    MOVE    #0,R0
  2935.         MOVE    #0,R4
  2936.         REP     #$7F
  2937.         MOVE    A,X:(R0)+   A,Y:(R4)+   ;Clear X & Y internal RAM
  2938.  
  2939. ; X memory initialization
  2940.  
  2941.         MOVE    #$3E2000,X0
  2942.         MOVE    X0,X:AP_T           ;Initialize AP_T & AP_R
  2943.         MOVE    A0,X:AP_R
  2944.         MOVE    #DATA_T,A0          ;Set transmit data pointer
  2945.         MOVE    A0,X:DATAPTR_T      ; to start of transmit data buffer
  2946.         MOVE    #DATA_R,A0          ;Set receive data pointer
  2947.         MOVE    A0,X:DATAPTR_R      ; to start of receive data buffer
  2948.         MOVE    #VARINIT,R0
  2949.         MOVE    #QUANTAB,R3
  2950.         DO      #38,XTABLES
  2951.         MOVE    P:(R0)+,X0          ;Transfer constant tables
  2952.         MOVE    X0,X:(R3)+          ; into X memory
  2953. XTABLES
  2954.         MOVE    #DATA_T+1,R3
  2955.         MOVE    #<$4,X0
  2956.         MOVE    #<$8,X1
  2957.         DO      #6,XBUFFER1
  2958.         MOVE    X0,X:(R3)+          ;Initialize SRnMANT and SRnS vars
  2959.         MOVE    X1,X:(R3)+          ; in the transmit data buffer
  2960.         MOVE    (R3)+
  2961. XBUFFER1
  2962.         MOVE    X0,X:(R3)+          ;Initialize SR1MANT (transmit)
  2963.         MOVE    (R3)+
  2964.         MOVE    (R3)+
  2965.         MOVE    X0,X:(R3)+          ;Initialize SR2MANT (transmit)
  2966.         MOVE    #DATA_R+1,R3
  2967.         DO      #6,XBUFFER2
  2968.         MOVE    X0,X:(R3)+          ;Initialize SRnMANT and SRnS vars
  2969.         MOVE    X1,X:(R3)+          ; in the receive data buffer
  2970.         MOVE    (R3)+
  2971. XBUFFER2
  2972.         MOVE    X0,X:(R3)+          ;Initialize SR1MANT (receive)
  2973.         MOVE    (R3)+
  2974.         MOVE    (R3)+
  2975.         MOVE    X0,X:(R3)+          ;Initialize SR2MANT (receive)
  2976.  
  2977. ; Y memory initialization
  2978.  
  2979.         MOVE    #$088000,X0
  2980.         MOVE    X0,Y:YU_T           ;Initialize YU_T,
  2981.         MOVE    X0,Y:YL_T           ; & YL_T
  2982.         MOVE    X0,Y:YU_R           ;Initialize YU_R,
  2983.         MOVE    X0,Y:YL_R           ; & YL_R
  2984.         MOVE    #RSHFT,R3
  2985.         DO      #56,YTABLES
  2986.         MOVE    P:(R0)+,X0          ;Transfer constant tables
  2987.         MOVE    X0,Y:(R3)+          ; into Y memory
  2988. YTABLES
  2989.  
  2990. ; Address register initialization
  2991.  
  2992.         MOVEC   #7,M1               ;Set partial product buffer for mod(7)
  2993.         MOVEC   #23,M2              ;Set data buffer for mod(23)
  2994.         MOVEC   #7,M6               ;Set coef buffer for mod(7)
  2995.         MOVEC   #$7F,M3             ;Set PCM table for mod(127)
  2996.         MOVE    #0,A                ;Select mu-law or A-law,
  2997.         MOVE    A,Y:LAW             ; for mu-law set LAW=0 (default),
  2998.                                     ; for A-law set LAW!=0
  2999.         TST     A       #$100,R3    ;If LAW=0 select mu-law table
  3000.         JEQ     <SETR5              ; base (in X ROM), otherwise
  3001.         MOVE    #$180,R3            ; select A-law table base
  3002. SETR5   MOVE    #RSHFT,R5           ;Set right shift table base
  3003.         RTS
  3004.  
  3005. ;QUANTAB
  3006. VARINIT     DC      $F84000         ;-0.98
  3007.             DC      $050000         ;0.62
  3008.             DC      $0B2000         ;1.38
  3009.             DC      $0F6000         ;1.91
  3010.             DC      $12C000         ;2.34
  3011.             DC      $15D000         ;2.72
  3012.             DC      $190000         ;3.12
  3013.             DC      $7FFFFF         ;15.99
  3014. ;IQUANTAB
  3015.             DC      $800000         ;-16    |I|=0
  3016.             DC      $004000         ;0.031  |I|=1
  3017.             DC      $087000         ;1.05   |I|=2
  3018.             DC      $0D5000         ;1.66   |I|=3
  3019.             DC      $111000         ;2.13   |I|=4
  3020.             DC      $143000         ;2.52   |I|=5
  3021.             DC      $175000         ;2.91   |I|=6
  3022.             DC      $1A9000         ;3.32   |I|=7
  3023. ;WIBASE
  3024.             DC      $FF4000         ;-0.75  |I|=0
  3025.             DC      $012000         ;1.13   |I|=1
  3026.             DC      $029000         ;2.56   |I|=2
  3027.             DC      $040000         ;4.00   |I|=3
  3028.             DC      $070000         ;7.00   |I|=4
  3029.             DC      $0C6000         ;12.38  |I|=5
  3030.             DC      $163000         ;22.19  |I|=6
  3031.             DC      $462000         ;70.13  |I|=7
  3032. ;TAB
  3033.             DC      $1E0000
  3034.             DC      $3E0000
  3035.             DC      $5E0000
  3036.             DC      $7E0000
  3037.             DC      $9E0000
  3038.             DC      $BE0000
  3039.             DC      $DE0000
  3040.             DC      $FE0000
  3041. ;CONST - constants used in FMULT
  3042.             DC      $FFFC00         ;KF1 = trunc mask
  3043.             DC      $7FFC00         ;KF2 = trunc mask
  3044.             DC      $018000         ;KF3 = '48'
  3045.             DC      $7F8000         ;KF4 = trunc mask
  3046.             DC      $00001A         ;KF5 = '26'
  3047.             DC      $7FFF00         ;KF6 = trunc mask
  3048.  
  3049. ;RSHFT
  3050.             DC      $800000
  3051.             DC      $400000         ;>>1    <<23
  3052.             DC      $200000         ;>>2    <<22
  3053.             DC      $100000         ;>>3    <<21
  3054.             DC      $080000         ;>>4    <<20
  3055.             DC      $040000         ;>>5    <<19
  3056.             DC      $020000         ;>>6    <<18
  3057.             DC      $010000         ;>>7    <<17
  3058.             DC      $008000         ;>>8    <<16
  3059.             DC      $004000         ;>>9    <<15
  3060.             DC      $002000         ;>>10   <<14
  3061.             DC      $001000         ;>>11   <<13
  3062.             DC      $000800         ;>>12   <<12
  3063.             DC      $000400         ;>>13   <<11
  3064.             DC      $000200         ;>>14   <<10
  3065.             DC      $000100         ;>>15   <<9
  3066.             DC      $000080         ;>>16   <<8
  3067.             DC      $000040         ;>>17   <<7
  3068.             DC      $000020         ;>>18   <<6
  3069.             DC      $000010         ;>>19   <<5
  3070.             DC      $000008         ;>>20   <<4
  3071.             DC      $000004         ;>>21   <<3
  3072.             DC      $000002         ;>>22   <<2
  3073.             DC      $000001         ;>>23   <<1
  3074. ;CONST1
  3075.             DC      $FFFE00         ;K1 = trunc mask (ACCUM)
  3076.             DC      $7FFC00         ;K2 = trunc mask (MIX)
  3077.             DC      $7FFE00         ;K3 = trunc mask (MIX)
  3078.             DC      $000080         ;K4 = shift const (EXPAND)
  3079.             DC      $00007F         ;K5 = sign mask (EXPAND)
  3080.             DC      $3F8000         ;K6 = trunc mask (LOG)
  3081.             DC      $100000         ;K7 = shift const (LOG)
  3082.             DC      $7FF000         ;K8 = trunc mask (SUBTB & ADDA)
  3083.             DC      $07F000         ;K9 = sign mask (ANTILOG)
  3084.             DC      $00000A         ;K10 = '10' (ANTILOG)
  3085.             DC      $7FFE00         ;K11 = trunc mask (ANTILOG)
  3086.             DC      $07C000         ;K12 = trunc mask (TRANS)
  3087.             DC      $000010         ;K13 = shift const (TRANS)
  3088.             DC      $000008         ;K14 = '8' (TRANS)
  3089.             DC      $000005         ;K15 = '5' (TRANS)
  3090.             DC      $7FFE00         ;K16 = trunc mask (TRANS)
  3091.             DC      $008000         ;K17 = +gain (UPB)
  3092.             DC      $FF8000         ;K18 = -gain (UPB)
  3093.             DC      $FFFF00         ;K19 = trunc mask (UPB)
  3094.             DC      $1FFF00         ;K20 = '+1.99' (UPA2)
  3095.             DC      $E00100         ;K21 = '-1.99' (UPA2)
  3096.             DC      $FFFF00         ;K22 = trunc mask (UPA2)
  3097.             DC      $FF4000         ;K23 = -gain (UPA1)
  3098.             DC      $00C000         ;K24 = +gain (UPA1)
  3099.             DC      $FFFF00         ;K25 = trunc mask (UPA1)
  3100.             DC      $040000         ;K26 = shift const (FILTA)
  3101.             DC      $FFF800         ;K27 = trunc mask (FILTA)
  3102.             DC      $FFFE00         ;K28 = trunc mask (FILTB)
  3103.             DC      $FFE000         ;K29 = trunc mask (FILTC)
  3104.             DC      $FFFC00         ;K30 = trunc mask (FILTD)
  3105.             DC      $088000         ;K31 = '1.06' (LIMB)
  3106.             DC      $FFFC00         ;K32 = trunc mask (FILTE)
  3107.